使用前面博客中建立的用户归档数据表来实验这个功能。在全局脚本中新建一个项目模块，用于读取数据表记录集，名字为GetSqlData,vbs代码如下：

Sub GetSqlData(rs,DBName,ssql)
Dim ocom,scon,conn
Dim PCName
Set PCName=HMIRuntime.Tags("@LocalMachineName")
scon="Provider = SQLOLEDB.1;Integrated Security=SSPI;Persist SecurityInfo=False;Initial Catalog ='" _
      & DBName & "';Data Source = " & PCName.Read  & "\WINCC"
Set conn=CreateObject("ADODB.Connection")
conn.ConnectionString=scon
conn.Cursorlocation=3
conn.open
Set rs=CreateObject("ADODB.RecordSet")
Set ocom=CreateObject("ADODB.Command")
ocom.commandtype=1
Set ocom.ActiveConnection=conn
ocom.CommandText=ssql
Set rs=ocom.Execute
End Sub

在画面上放置一个listview控件，名字修改为LV。放置一个按钮，按钮的鼠标点击事件中添加以下vbs脚本

Sub OnClick(ByVal Item)         
Dim ctrlLV
Dim DBName,ssql,rs
Dim RsCount,i
Set ctrlLV=ScreenItems("LV")
Set DBName=HMIRuntime.Tags("@DatasourceNameRT")
Set rs=Createobject("ADODB.RecordSet")
ssql="select top 100 ID,Curdate as '日期',Curtime as '时间',FT101 as '流量1' from UA#UA"  '选择前100条记录

'获取记录集
getSqlData rs,DBName.Read ,ssql
RsCount=rs.RecordCount
ctrlLV.View =3 '设置外观为报表形式
ctrlLV.GridLines =True '显示网格线
ctrlLV.ColumnHeaders.Clear '清楚原有表头
With ctrlLv.ColumnHeaders
    .add ,,"",10
    .add ,,"ID",100
    .add ,,"日期",100
    .add ,,"时间",100
    .add ,,"流量1",100
End With
ctrlLV.listitems.clear  '清除原有数据
rs.movefirst
For i=1 To RsCount
 With ctrlLv.listitems.add
     .subitems(1)=rs.fields(0).value
     .subitems(2)=rs.fields(1).value
     .subitems(3)=rs.fields(2).value
     .subitems(4)=rs.fields(3).value
 End With
 rs.movenext
Next
End Sub

这个练习中，sql查询条件设置比较简单，只是为了练习listview行列的填充功能，代码很好理解，也没有写过多的注释。