Oracle 动态SQL语句_幽兰静

http://blog.sina.com.cn/u/1809307971

首页博文目录关于我

个人资料

微博

加好友发纸条

写留言加关注

博客等级：
博客积分：

博客访问：
关注人气：
获赠金笔：0支
赠出金笔：0支
荣誉徽章：

正文字体大小：大中小

Oracle 动态SQL语句

(2012-06-18 16:36:12)

标签：

oracle

it

EXECUTE IMMEDIATE 代替了以前Oracle8i中DBMS_SQL package包.
它解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.动态创建和执行SQL语句性能超前，EXECUTE IMMEDIATE的目标在于减小企业费用并获得较高的性能，较之以前它相当容易编码.尽管DBMS_SQL仍然可用，但是推荐使用EXECUTE IMMEDIATE,因为它获的收益在包之上。

-- 使用技巧

1. EXECUTE IMMEDIATE将不会提交一个DML事务执行，应该显式提交
如果通过EXECUTE IMMEDIATE处理DML命令，
那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分.
如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据

2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.

3. 当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号.

4. 在Oracle手册中，未详细覆盖这些功能。
下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.

5. 对于Forms开发者,当在PL/SQL 8.0.6.3.版本中，Forms 6i不能使用此功能.

EXECUTE IMMEDIATE -- 用法例子

1. 在PL/SQL运行DDL语句

begin
   execute immediate 'set role all';
end;

2. 给动态语句传值(USING 子句)

declare
   l_depnam varchar2(20) := 'testing';
   l_loc     varchar2(10) := 'Dubai';
   begin
   execute immediate 'insert into dept values   (:1, :2, :3)'
     using 50, l_depnam, l_loc;
   commit; -----一定要显示提交
end;

3. 从动态语句检索值(INTO子句)

declare
   l_cnt     varchar2(20);
begin
   execute immediate 'select count(1) from emp'
     into l_cnt;
   dbms_output.put_line(l_cnt);
end;

4. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.
黓认为IN类型,其它类型必须显式指定

declare
   l_routin    varchar2(100) := 'gen2161.get_rowcnt';
   l_tblnam    varchar2(20) := 'emp';
   l_cnt       number;
   l_status    varchar2(200);
begin
   execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
     using in l_tblnam, out l_cnt, in out l_status;
   if l_status != 'OK' then
      dbms_output.put_line('error');
   end if;
end;

5. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量

declare
   type empdtlrec is record (empno   number(4),
                            ename   varchar2(20),
                            deptno   number(2));
   empdtl empdtlrec;
begin
   execute immediate 'select empno, ename, deptno ' ||
                    'from emp where empno = 7934'
     into empdtl;
end;

6. 传递并检索值.INTO子句用在USING子句前

declare
   l_dept     pls_integer := 20;
   l_nam      varchar2(20);
   l_loc      varchar2(20);
begin
   execute immediate 'select dname, loc from dept where deptno = :1'
     into l_nam, l_loc
     using l_dept ;
end;

7. 多行查询选项.对此选项用insert语句填充临时表，
用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.
declare
   l_sal    pls_integer := 2000;
begin
   execute immediate 'insert into temp(empno, ename) ' ||
                    '           select empno, ename from emp ' ||
                    '           where   sal > :1'
     using l_sal;
   commit;
end;

        对于处理动态语句,EXECUTE IMMEDIATE 比以前可能用到的更容易并且更高效.
当意图执行动态语句时，适当地处理异常更加重要.应该关注于捕获所有可能的异常.

Oracle的动态SQL和动态游标举例：

--动态sql和动态游标

declare

cnt number;

begin

execute immediate

'select count(*) from emp'

into cnt;

dbms_output.put_line(cnt);

end;

--创建存储过程执行插入语句

create or replace procedure myproc11

(empid in varchar2,empname in varchar2)

sql_str varchar(200):='insert into emp values(:a,:b)';

begin

execute immediate sql_str using empid,empname;

commit;

end;

--本过程有两个参数，第一个表示查询类型：0-精确查询 1-模糊查询；

--第二个参数表示查询条件

create or replace procedure myproc12

(query_type in number,empname in varchar2)

sql_str varchar(200):='select * from emp ';

cur pck1.myrefcur;

e emp%rowtype;

begin

if query_type=0 then

sql_str:=sql_str||'where emp_name=:1';

else

sql_str:=sql_str||'where emp_name like ''%''||:1||''%''';

end if;

dbms_output.put_line(sql_str);

open cur for sql_str using empname;

loop

fetch cur into e;

exit when cur%notfound;

dbms_output.put_line(e.emp_id||','||e.emp_name);

end loop;

close cur;

end;

--按姓名模糊查询记录总数

create or replace procedure myproc20

(ename in varchar2)

cnt number;

begin

execute immediate

'select count(*) from emp where emp_name like ''%''||:n||''%'''

into cnt using ename;

dbms_output.put_line(cnt);

end;

使用execute immediate语句可以处理包括ddl（create、alter和drop）、DCL（grant、revoke）、DML（insert、update、delete）以及单行select语句。

execute immediate语句：
       execute immediate dynamic_string
       [into {define_variable[,define_variable]…|record}]
       [using [in|out|in out] bind_argument[,[in|out|in out] bind_argument]…]
       [{returning|return} into bind_argument[, bind_argument]…]

Define_variable用于指定存放单行查询结果的变量；

using in bind_argument用于指定存放传递给动态sql值的变量，即在dynamic中存在占位符时使用；

using out bind_argument用于指定存放动态sql返回值的变量。

示例：使用execute immediate执行简单ddl语句
begin

execute immediate 'create table ma_org(org_code varchar2(20),org_name varchar2(254))';
execute immediate 'drop table ma_org';
end;

实例：使用execute immediate执行dcl语句
    begin
        execute immediate 'grant insert on ma_org to scott'
    end;

示例：使用execute immediate处理dml语句。

如果dml语句包含占位符，那么在execute immediate语句之后必须要带有using子句；如果dml语句带有returning子句，那么在execute immediate语句之后必须带有returning into子句，并且此时只能处理作用的单行上的dml语句，如果dml语句作用在多行上，则必须使用bulk子句。

示例：

declare
          orgcode varchar2(10);
          orgname varchar2(254);
    begin
          orgcode := 1200;
          execute immediate 'select org_name from ma_org
          where org_code = :X'
          into orgname
          using orgcode;
          dbms_output.put_line(orgname);
    end;

示例：

declare
          orgcode varchar2(10);
          orgname varchar2(254);
          rname varchar2(254);
    begin
          orgcode := '1200';
          orgname := '天津市分行';
          execute immediate 'update ma_org set org_name= :X
          where org_code = :Y returning org_name into :rname'
          using orgname, orgcode
          returning into rname;
          dbms_output.put_line(orgname);
    end;

使用动态游标处理多行查询类动态sql语句。

示例：

declare
          type myrefcursor is ref cursor;
          refcursor myrefcursor;
          rec_ma_org ma_org%rowtype;
    begin
          open refcursor for select * from ma_org;
               loop
                   fetch refcursor into rec_ma_org;
                   exit when refcursor%notfound;
                   dbms_output.put_line(rec_ma_org.org_code||','||rec_ma_org.org_name);
               end loop;
          close refcursor;
    end;

oracle通过使用bulk collect into子句处理动态sql中的多行查询可以加快处理速度，从而提高应用程序的性能。当使用bulk子句时，集合类型可以是plsql所支持的索引表、嵌套表和varray，但集合元素必须使用sql数据类型。在oracle9i以后，有三种语句支持bulk子句，execute immediate，fetch和forall。

在execute immediate中使用bulk collect into处理多行查询返回结果:

示例：

declare
          type org_table_type is table of ma_org%rowtype;
          org_table org_table_type;
          v_orgcode varchar2(20);
    begin
          v_orgcode := '%';
          execute immediate 'select * from ma_org where org_code like :v_orgcode' bulk collect into org_table
          using v_orgcode;
          for i in 1..org_table.count
              loop
                 dbms_output.put_line(org_table(i).org_code||','||org_table(i).org_name);
              end loop;
    end;

在forall语句中使用bulkinto语句。

示例：

declare
          type type_org_code is table of ma_org.org_code%type;
          type type_org_name is table of ma_org.org_name%type;
          v_orgcode type_org_code;
          v_orgname type_org_name;
    begin
          v_orgcode := type_org_code('1100','1200');
          forall i in 1..v_orgcode.count
             execute immediate 'update ma_org set org_name = org_code||org_name where org_code = :p1 returning org_name into :p2'
             using v_orgcode(i)
             returning bulk collect into v_orgname;
          for i in v_orgname.first..v_orgname.last
             loop
                dbms_output.put_line(v_orgname(i));
          end loop;
    end;

阅读┊ 收藏 ┊ 喜欢 ▼ ┊打印┊举报/Report

前一篇：oracle 查询特殊命令

后一篇：[转载]Oracle Decode函数详解

新浪BLOG意见反馈留言板　欢迎批评指正