前些天的一些突发事件，使得我发现了Z-Blog存在的一个很严重的性能问题，就是当单篇文章日访问量数万的时候，会有大量并发用户同时写Access数据库，会导致数据库死锁，之后的外在表现就是CPU占用猛增。

　　经过对Z-Blog的代码进行分析，我发现其原因是大并发用户同时写数据库产生的原因。

　　我这里想到了一个针对这个问题的解决方案，就是时间缓存，定时写数据库，在一定时间内，数据只写入内存，不写入数据库，当缓存时间到了以后，再把内存的数据写入数据库。这样，即使再大的并发量，也不会再发生数据库死锁的问题了。

　　经过初步的代码修改和测试，发现修改完了以后就没有这个问题了。

　　修改方法是，打开FUNCTION目录下的c_html_js.asp文件，修改UpdateCountInfo函数为以下代码即可。

Function UpdateCountInfo(id)

 Dim strLastUpdate

 Dim intArticleCount

 Dim aryArticleCount

 Dim objRS

 Application.Lock

 strLastUpdate=Application(ZC_BLOG_CLSID&"LAST_UPDATE")

 aryArticleCount=Application(ZC_BLOG_CLSID&"CACHE_ARTICLE_VIEWCOUNT")

 aryArticleCount(id)=aryArticleCount(id)+1

 Application(ZC_BLOG_CLSID&"CACHE_ARTICLE_VIEWCOUNT")=aryArticleCount

 Application.UnLock

 If IsEmpty(strLastUpdate) Or Not IsDate(strLastUpdate) Then

  Application.Lock

  Application(ZC_BLOG_CLSID&"LAST_UPDATE") = Now()

  strLastUpdate = Application(ZC_BLOG_CLSID&"LAST_UPDATE")

  Application.UnLock

 End If

 If DateDiff("s",strLastUpdate,Now()) > 30 Then

 '如果当前时间与上次保存计数值的时间差大于设定的时间间隔，则把计数值重新写入数据库

  Call OpenConnect()

  Set objRS=objConn.Execute("SELECT [log_ID],[log_ViewNums] FROM [blog_Article] WHERE [log_ID] =" & id)

  If (not objRS.bof) And (not objRS.eof) Then

   intArticleCount=objRS("log_ViewNums")

  Else

   intArticleCount=0

  End If

  objRS.Close

  Set objRS=Nothing

  If aryArticleCount(id) > intArticleCount Then

   objConn.Execute("UPDATE [blog_Article] SET [log_ViewNums]=" & CStr(aryArticleCount(id)) & " WHERE [log_ID] =" & id)

   Application.Lock

   Application(ZC_BLOG_CLSID&"LAST_UPDATE") = Now()

   Application.UnLock

  Else

   aryArticleCount(id) = intArticleCount

   Application.Lock

   Application(ZC_BLOG_CLSID&"CACHE_ARTICLE_VIEWCOUNT")=aryArticleCount

   Application.UnLock

  End If

  Call CloseConnect()

 End If

End Function

　　另外，默认的Z-Blog留言评论是没有用户IP地址显示的，通过一些修改，可以在留言中增加用户IP地址前三位的显示功能，具体实现方法如下。

　　修改c_system_lib.asp文件的Public Function MakeTemplate(strC)函数，加入下面语句：

  ReDim aryTemplateTagsName(12)

  ReDim aryTemplateTagsValue(12)

  aryTemplateTagsName( 12)="article/comment/ip"

  if AuthorID=1  then

   aryTemplateTagsValue(12)=""

  else

   aryTemplateTagsValue(12)="ip：" + Left(IP, InStrRev(IP, ".")) + "*"

  end if

　　修改TArticle的Function Export_CMTandTB()函数，将 objComment.LoadInfoByArray(Array(objRS("comm_ID"),objRS("log_ID"),objRS("comm_AuthorID"),objRS("comm_Author"),objRS("comm_Content"),objRS("comm_Email"),objRS("comm_HomePage"),objRS("comm_PostTime"),"","")) 改为 objComment.LoadInfoByArray(Array(objRS("comm_ID"),objRS("log_ID"),objRS("comm_AuthorID"),objRS("comm_Author"),objRS("comm_Content"),objRS("comm_Email"),objRS("comm_HomePage"),objRS("comm_PostTime"),objRS("comm_IP"),""))

　　修改 b_article_comment.html ，增加 <#article/comment/ip#>标签。

　　之后，文章评论就会出现评论者的IP地址栏，不过有个问题是，当评论有人回复的是时候，只能留下最后一个回复者的IP地址。

原创文章如转载，请注明：转载自月光博客 [ http://www.williamlong.info/ ]

本文链接地址：http://www.williamlong.info/archives/2062.html