加载中…
魔兽世界详尽的牧师竞技场宏命令
(2008-05-17 11:19:58)
标签：
jjc竞技场燃烧的远征tbc燃烧远征牧师天赋宏命令编写游戏 |
分类： 魔兽世界专辑 |
/castsequence
真言术：韧,神圣之灵,防护暗影
战场和竞技场准备时间加buff用，按一次加一个buff。
/castsequence 真言术：韧(等级
1),神圣之灵(等级 1),防护暗影(等级 1)
开战后补buff宏，对付对方的进攻驱散保队友buff用。
慎用，珍惜公共CD。
治疗：
/cast [modifier:alt,target=player] 强效治疗术
/cast [help] 强效治疗术; [target=targettarget]
强效治疗术
无论目标是谁，按alt+对自己施放强效治疗
目标是友方时，对目标施放强效治疗
目标敌对，对目标的目标施放强效治疗
同样，可以改成快速治疗，痛苦压制等等。
/cast [modifier:alt,target=player] 快速治疗
/cast [help] 快速治疗; [target=targettarget]
快速治疗
暗影魔：
#show 暗影恶魔
/cast 暗影恶魔
/petattack
/petdefensive
暗影魔召出后攻击目标，改防御模式。
这样暗影魔就不会因为别人攻击了牧师而换目标了。
能量灌注：
#show 能量灌注
/stopcasting
/cast [modifier:alt,target=player] 能量灌注
/cast [target=队友名字] 能量灌注
/cast [help] 能量灌注
按alt+对自己施放能量灌注
否则不论当前目标是谁，对事先输入名字的队友施放能量灌注
最后一行是我打战场懒得改按键了加进去的，当队友不在时对当前目标施放能量灌注
3V3贼法牧组合用这个宏相当舒服，其他场合不好用……还是点了人再加灌注吧。
或者可以改成这样：
#show 能量灌注
/stopcasting
/cast [modifier:alt,target=player] 能量灌注
/cast [modifier:shift,target=队友A] 能量灌注
/cast [modifier:ctrl,target=队友B] 能量灌注
/cast [target=队友C] 能量灌注
/cast [help] 能量灌注
按alt+给自己，按shift+给队友A，ctrl+给队友B，直接按给队友C。
#show 能量灌注
/stopcasting
/施放 [target=player]能量灌注
/stopcasting
/use 13
灌注+开护符
护符放在饰品的上面位置就是13，下面是14
补充一个戒律牧22 33补刀宏……
特别是和贼搭22的时候好用，因为灌注只能给自己-v-
/cast [modifier:alt,target=player]能量灌注
/cast [modifier:alt]13
/castsequence 心灵震暴(等级 11),暗言术：灭(等级
2)
不按alt的时候是常规的辅助dps，按下alt就是关键时刻的爆发补刀。
/stopcasting
/cast 群体驱散
大驱散宏，作用是避免鼠标同时多点造成的驱散范围选框消失
/cast [target=targettarget] 驱散魔法
驱散目标的目标
/cast [modifier:alt,target=player] 驱散魔法
/cast [help] 驱散魔法; [harm] 驱散魔法
经常看到求alt+驱散自己，直接按驱散目标的宏，就是这个。
其实这个宏完全没必要，设置alt+自我施法就可以了……不过既然要的人多，还是放出。
焦点相关：
#show 沉默
/stopcasting
/cast [target=focus,exists] 沉默
焦点沉默宏
#show 暗言术：灭
/stopcasting
/cast [target=focus,exists] 暗言术：灭
灭焦点宏
灭破羊，破陷阱破盲....
#show 暗言术：灭
/stopcasting
/cast [target=focus,exists,harm,nodead]
暗言术：灭;[harm,nodead]暗言术：灭
复杂一点的灭焦点宏
焦点已死就灭当前目标
如果使用系统默认动作条，为了节约动作条位置不想把灭当前目标和灭焦点设置成2个键，就这样：
#show 暗言术：灭
/stopcasting
/cast
[modifier:alt,harm,nodead]暗言术：灭;[target=focus,exists,harm,nodead]
暗言术：灭;[harm,nodead]暗言术：灭
按alt灭当前目标
直接按灭焦点
#show 暗言术：灭
/stopcasting
/cast [target=mouseover,exists,harm,nodead]
暗言术：灭;[modifier:alt,harm,nodead]暗言术：灭;[target=focus,exists,harm,nodead]
暗言术：灭;[harm,nodead]暗言术：灭
加入鼠标指向目标的再复杂一点的暗言灭宏
优先灭鼠标指向目标
如果没有，灭焦点
如果焦点死了……灭当前目标
任何时候按alt+，灭当前目标
这个加上了目标是否已挂了的判定，作用是在焦点目标挂了，灭鼠标指向目标的时候那个也刚好挂了的时候，不会灭当前目标，防止意外的破控制技事件发生。
使用物品/种族技能：
/use 13
/use 极效治疗石
开战斗大师同时吃治疗石，同样，饰品上栏是13下栏是14
/stopcasting
/cast 石像形态
/cast 绝望祷言
这个和上面那个可以结合起来用
/use [target=player]厚灵纹布绷带
绷带宏
#show 亡灵意志
/targetlasttarget
/cast 亡灵意志
亡灵意志宏，作用是在被恐惧时意志并且找回恐惧前的目标，因为被恐惧会丢失目标。
#show 噬灵瘟疫
/stopcasting
/cast 心灵专注
/cast 噬灵瘟疫
专注+瘟疫宏，如果要开护符丢，加一句/use
13进去
喜欢
0
赠金笔