用COUNTBLANK函数，如=COUNTBLANK(A1:F30)

计算区域内单元格有数值的个数：count

计算区域内不重复内容的单元格个数：=SUMPRODUCT(1/COUNTIF(B1:B9,B1:B9))

满足条件的单元格个数的函数COUNTIF

EXCEL COUNTIF 函数
统计函数之: COUNTIF 函数
　　    
1、简要说明：     
 计算给定区域内满足特定条件的单元格的数目
 　 　 　 　 　
2、基本语法： 　
 =COUNTIF(区域,条件)
 区域：为需要计算其中满足条件的单元格数目的单元格区域
 条件：为确定哪些单元格将被计算在内的条件，其形式可以为数字、表达式或文本。
     
3、实例1：     
 题目： COUNTIF基础运用 　 　
   数据类型 
 Excel精英培训 -100 2 1 
 学习Excel 　 2 2 假空单元格为字符型
 200 　 1 1 真空单元格为数据型
 　 Excelpx　网 1 2 
 606 精英财务 1 2 
 　    1 2 含空格单元格为字符型
 财务学习 400 2 1 
 进入Excelpx 　　 2 2 
     
 题目公式结果简要说明             公式                                 结果                             
 求真空单元格的个数:         =COUNTIF($B$20:$C$27,"=")                    3 　
 求非真空单元格的个数:       =COUNTIF($B$20:$C$27,"<>")                   13 　
 求含空格单元格的个数        {=SUM(--(ASC(MID(B20:C26,1,1))=" "))}         2 这为一数组公式，可求出半角、全角空格，空格可能多于一个
 求为真空＋假空单元格的个数  =COUNTIF($B$20:$C$26,"")                       4 注：不包括空格单元格
 求为假空单元格的个数        =COUNTIF($B$20:$C$26,"")-COUNTIF($B$20:$C$26,"=")  1 　
 求为文本单元格的个数         =COUNTIF($B$20:$C$27,"*")                   9 注：不包括空格单元格
 求为数值单元格的个数         =COUNT($B$20:$C$27)                         4 注意：这里用的是count()函数，值不包括真空单元格
 求包含EXCEL的单元格的个数   =COUNTIF($B$20:$C$27,"*excel*")              4 所求字符可在任何位置
 求以EXCEL打头的单元格的个数  =COUNTIF($B$20:$C$27,"excel*")               2 *号代表任意字符
 求第三位是EXCEL的单元格的个数  =COUNTIF($B$20:$C$27,"??excel")            1 每一个?代表一个字符
 求大于等于200的单元格的数     =COUNTIF($B$20:$C$27,">="&200)               3 　
 求大于－100且小于606的单元格的数  =SUM(COUNTIF($B$20:$C$27,">"&{-100,606})*{1,-1}) 3 求一区间内值的个数
 求大于－100且小于606的单元格的数  =SUM(COUNTIF($B$20:$C$27,{">-100",">=606"})*{1,-1}) 2 求一区间内值的个数，countif函数中的条件可以是一条件组
     
     
4、实例2：     
 题目： 求不重复值个数 　 　
 EXCELPX    
 EXCEL精英培训网    
 EXCELPX    
 EXCEL    
 EXCEL精英培训网    
 EXCELPX    
 EXCEL精英培训网    
 EXCEL    
 公式： {=SUM(1/COUNTIF(B47:B54,B47:B54))} 　
     
 结果： 3 　 　 　
     
 简要说明　　COUNTIF(B47:B54,B47:B54)可以得到数据系列中各数据值的重复个数，再求其倒数和即可得到不重数据的个数6 `0 u2 w" }5 Y4 x5 w  d
　　公式是数组公式，需用EXCEL＋SHIFT＋ENTER同时按下才能生成
     
     
5、实例3：     
 题目： 利用countif()标记不重复的值 　
     
 公式： IF(COUNTIF(B$69:B69,B69)=1,1,"") 　
     
 结果： 　 　 　 　
 编号记号计算中间过程示例  
 a2111 1 1  
 a2111 　 2  
 a2112 1 1  
 a2151 1 1  
 a2112 　 2  
 a2122 1 1  
 a2122 　 2  
 a2123 1 1  
 a2123 　 2  
 a2131 1 1  
 a2131 　 2  
 a2141 1 1  
 a2141 　 2  
 a2141 　 3  
 a2141 　 4  
 a2141 　 5  
 a2151 　 2  
 a2151 　 3  
 a2151 　 4  
     
 简要说明： COUNTIF(B$69:B69,B69)中，B$69:B69固定首行的变动区域，countif计算值为1的即为首次计数的值
     
5、实例4：     
 题目： 利用countif()列出不重复的值（数据为延用“实例3”的数据）
     
 公式： INDEX($B$69:$B$87,MATCH(,COUNTIF(B$94:B94,$B$69:$B$87),))
     
 结果： 　 　 　 　
 a2111    
 a2112    
 a2151    
 a2122    
 a2123    
 a2131    
 a2141    
 　处理错误值   
 　处理错误值