网上发现“一个绝顶高手前辈的指标和大家一起分享(通达信)”的一个指标源码，如下：

买:=IF("KDJ.J"<0,10,0);
条件:=CROSS(9.9,买);
VAR1:=(2*CLOSE+HIGH+LOW)/4;
VAR2:=LLV(LOW,5);
VAR3:=HHV(HIGH,5);
VAR4:=EMA((VAR1-VAR2)/(VAR3-VAR2)*100,5);
MA1:=MA(VAR4,2);
AA:STICKLINE(VAR4>MA1,VAR4,MA1,6,1),COLORRED;
BBB:STICKLINE(VAR4>MA1 AND REF(VAR4,1)<30,VAR4,MA1,6,1),COLORRED;
STICKLINE(VAR4<=MA1,VAR4,MA1,6,1),COLORFFCC66;
DRAWICON(CROSS(9.9,买),VAR4-12,4);
STICKLINE(CROSS(9.9,买),VAR4+5,MA1-4,6,1),COLORYELLOW;
XXX:STICKLINE(VAR4>MA1 AND REF(VAR4,1)<30,VAR4+5,MA1-4,6,1),COLORYELLOW;

这几天学习了公式编写，就想着把她改为选股公式，先拿到通达信软件上测试，指标通过，可行！

买赋值:如果"KDJ的J"<0,返回10,否则返回0

条件赋值:9.9上穿买

VAR1赋值:(2*收盘价+最高价+最低价)/4

VAR2赋值:5日内最低价的最低值

VAR3赋值:5日内最高价的最高值

VAR4赋值:(VAR1-VAR2)/(VAR3-VAR2)*100的5日指数移动平均

MA1赋值:VAR4的2日简单移动平均

输出AA:当满足条件VAR4>MA1时,在VAR4和MA1位置之间画柱状线,宽度为6,1不为0则画空心柱.,画红色

输出BBB:当满足条件VAR4>MA1ANDREF(VAR4,1)<30时,在VAR4和MA1位置之间画柱状线,宽度为6,1不为0则画空心柱.,画红色

当满足条件VAR4<=MA1时,在VAR4和MA1位置之间画柱状线,宽度为6,1不为0则画空心柱.,COLORFFCC66

当满足条件9.9上穿买时,在VAR4-12位置画4号图标

当满足条件9.9上穿买时,在VAR4+5和MA1-4位置之间画柱状线,宽度为6,1不为0则画空心柱.,画黄色

输出XXX:当满足条件VAR4>MA1ANDREF(VAR4,1)<30时,在VAR4+5和MA1-4位置之间画柱状线,宽度为6,1不为0则画空心柱.,画黄色

 http://s14/mw690/4bcf6ebfgce8304c9ef5d&690

就试着改。。。。。。

改为选股公式如下：

买:=IF("KDJ.J"<0,10,0);
CROSS(9.9,买);

测试，可行！

原来如此，关键点只是个“超卖”！

以下是将公式改为选股公式的简易方法，求人不如求己嘛

（确实如此，同时谢谢不知名的共享提供者）

步骤一.将所有的显示式":",改为不显示式":="
选股条件的基本要求为只能输出1个条件式,故要先将公式中所有的显示式":"改为不显示式":=",
如果原来显示式后面接有线型描述(颜色.对齐..等),也一并删除
例如:
ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;
.....

先改为
ma1:=ma(c,5);
ma2:=ma(c,10);
.....

步骤二.找出选股条件,并写成选股式引用:
条件的寻找方法,依不同目的,大致可分以下几种:

1.'字'选股     如:'买'选股
方法:先找出公式中出现有'字'的地方,该式开头会以DRAW..TEXT开头,
DRAWTEXT  DRAWTEXTEX  DRAWYITEXT DRAWFLAGTEXT DRAWMOVETEXT
找到后,该函数(条件, ,'字')后面括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求'5日均>10日均'选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;

2.图标选股     如:笑脸选股
方法:
先依不同软件,找出该图标的代号,
再找出公式中出现DRAWICON函数(条件,   ,图标代号)的式子,对照图标的代号(括号内的第3个),如果该图标代号为所求代号,
该函数后面括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解]
ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;

3.A线上穿(下穿)B线选股  {上穿--金叉,下穿--死叉}
方法:A线上穿B线:  cross(A,B);
     A线下穿B线:  cross(B,A);
例如:
{求ma1上穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解] 
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);

{求ma1下穿ma2选股}
ma1:ma(c,5);
ma2:ma(c,10);
[解] 
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);


4.线A上穿(下穿) 选股  
方法:线A上穿:  cross(A,ma(A,2));    或  cross(A,ref(A,1));
     线A下穿:  cross(ma(A,2),A);    或  cross(ref(A,1),A);
例如:
{求改成ma1上穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));

{求改成ma1下穿}
ma1:ma(c,5);
[解]
ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或  
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);

5.第1次出现条件A 选股
方法:先找出条件A,
     再利用cross(A,0.5);

例如:
{求改成出现图标1选股}
ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);
[解1]
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5); 
[解2--直接将条件A写入]
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5); 

6.线变色选股   如:黄线变红色选股 (指标线为黄线,再利用函数变红色线)
方法:先依不同软件,找出条件A,
     再用cross(A,0.5);

(1)飞狐
条件在PARTLINE(条件A, ),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  飞狐}
ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(2)大智慧L2.分析家
条件在PARTLINE(  ,条件A,rgb(255,0,0),  , ...);
括号内为rgb(255,0,0)的前1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  大智慧L2.分析家}
ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));
[解]
ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

(3)通达信
条件在IF(条件A,   ,DRAWNULL),colorred;括号内的第1个即为条件,将该条件复制出来并加上分号即可
例如:
{求黄线变红色选股  通达信}
MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;
[解]
MA1:=MA(C,5);
A:=MA1>REF(MA1,1);
CROSS(MA1>REF(MA1,1),0.5);

7.颜色柱选股
方法:先找出公式中出现有STICKLINE函数的地方,
找到后,核对该函数后面的颜色,是否为所求颜色,
若颜色相同,则括号内的第1个即为条件A,将该条件复制出来并加上分号即可

例如:
{求红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:c>o;

{求第1次红色柱选股}
STICKLINE(c>o,h,l,0.8,1),colorred;
[解]
A:=c>o;
cross(A,0.5);

步骤三.最后将所有绘图函数及单一输出值(如 0;  k;  if(,,); )全删除,使公式只剩1个选股式输出即成,
(若有2个以上条件,条件同时成立时,可在条件间用"and"连接;
  若有2个以上条件,允许条件不同时成立时,可在条件间用"or"连接)；