/FILENAME,E411
/TITLE,TOWER
*CREATE,TOWER,MAC   !创建宏文件TOWER
!***************环境设置**************
!*********几何参数，单位mm************
*SET,ta_R,3000    !塔半径
*SET,outlet_R,1000    !出口半径
*SET,outlet_h,5452    !出口高度
*SET,low_h,16000    !下筒体高度
*SET,up_h,5000    !上筒体高度
*SET,qun_h,2650    !裙座高度
*SET,low_t,32    !下筒体厚度
*SET,up_t,28    !上筒体厚度
!*********其他参数********************
*SET,omega,1.5    !风激励角速度
!*********前处理**********************
/PREP7
!********定义单元类型材料常数等********
ET,1,SHELL63    !定义1号单元
ET,2,SOLID45    !定义2号单元
MP,EX,1,1.824859E5    !定义1号材料弹性模量
MP,PRXY,1,0.3    !定义1号材料泊松比
MP,DENS,1,7.85E-6    !定义1号材料密度
MP,EX,2,420    !定义2号材料弹性模量
MP,PRXY,2,0.3    !定义2号材料泊松比
MP,DENS,2,0.8E-6    !定义2号材料密度
R,1,low_t,low_t,low_t,low_t   !定义1号实常数
R,2,up_t,up_t,up_t,up_t   !定义2号实常数
!*************几何建模****************
!***********塔壁实体建模**************
/PNUM,KP,1    !打开关键点编号显示开关
/PNUM,LINE,1    !打开线编号显示开关
/PNUM,AREA,1    !打开面编号显示开关
!***********建立塔的关键点***************
K,1,outlet_R    !生成塔壁的1号关键点,坐标(outlet_R,0,0)
K,2,ta_R,outlet_h    !建立2号关键点,坐标(ta_R,outlet_h,0)
K,3,ta_R,outlet_h+low_h   !建立3号关键点,坐标(ta_R,outlet_h+low_h，0)
K,4,ta_R,outlet_h+low_h+up_h !建立4号关键点,坐标(ta_R,outlet_h+low_h+up_h，0)
K,5,ta_R,outlet_h-qun_h   !建立5号关键点,坐标(ta_R,outlet_h-qun_h，0)
K,6,,outlet_h+low_h+up_h   !建立6号关键点,坐标(0,outlet_h+low_h+up_h，0)
K,7,,outlet_h+low_h+up_h+ta_R !建立7号关键点,坐标(0,outlet_h+low_h+up_h+ta_R，0)
K,1000     !建立1000号关键点,坐标(0,0,0)
!***********建立塔的线****************
L,1,2     !连接1,2关键点生成1号线
L,2,3     !连接2,3关键点生成2号线
L,3,4     !连接3,4关键点生成3号线
L,2,5     !连接2,5关键点生成4号线
LARC,4,7,6,ta_R    !以ta_R为半径，4,7号关键点为终点建立弧线,圆心位于6号点一侧
!***********旋转生成塔体**************
AROTAT,1,2,3,5,,,1000,6,,   !以1000与6号点连线为轴线将1,2,3,5号线旋转为塔面
AROTAT,4,,,,,,1000,6,,   !以1000与6号点连线为轴线将4号线旋转为塔面
!*************划分网格****************
LSEL,S,LOC,Y,0    !以Y坐标为“0”选取线
LSEL,A,LOC,Y,outlet_h-qun_h   !以Y坐标为“outlet_h-qun_h”增选线
LSEL,A,LOC,Y,outlet_h   !以Y坐标为“outlet_h”增选线
LSEL,A,LOC,Y,outlet_h+low_h   !以Y坐标为“outlet_h+low_h”增选线
LSEL,A,LOC,Y,outlet_h+low_h+up_h !以Y坐标为“outlet_h+low_h+up_h”增选线
LESIZE,ALL,,,12    !设置所选择线的划分份数为12份
CSYS,5     !切换到以Y轴为旋转轴的坐标系
LSEL,S,LOC,X,outlet_R+1,ta_R-1 !以X坐标选择在“outlet_R+1,ta_R-1”范围内的线
LSEL,A,LOC,Z,outlet_h+low_h+1,outlet_h+low_h+up_h-1   !增选线
LSEL,U,LOC,Z,outlet_h+low_h+up_h,outlet_h+low_h+up_h+ta_R !反选线
LESIZE,ALL,,,12    !设置所选择线的划分份数为12份
LSEL,S,LOC,Z,outlet_h-qun_h+1,outlet_h-1    !新选线
LESIZE,ALL,,,8    !设置所选择线的划分份数为8份
LSEL,S,LOC,Z,outlet_h+1,outlet_h+low_h-1    !新选线
LESIZE,ALL,,,40    !设置所选择线的划分份数为40份
ALLS     !选中所有的元素
ASEL,S,LOC,Z,0,low_h   !选择z坐标范围在0到low_h之间的面
REAL,1     !指定将划分单元的实常数为1
MSHKEY,1     !指定单元划分方式为映射网格
MSHAPE,0,3D    !指定单元形状2D为4边形，3D为六面体。
AMESH,ALL     !划分所有选中的面
ASEL,S,LOC,Z,low_h+outlet_h,low_h+up_h+qun_h+outlet_h   !新选面
REAL,2     !指定将划分单元的实常数为2
AMESH,ALL     !划分所有选中的面
ALLS     !选中所有的元素
NUMMRG,ALL    !合并所有重合元素
NUMCMP,ALL    !压缩所有元素的编号
!************生成焦炭单元*************
CSYS     !回到柱坐标系
K,1001,,outlet_h,,    !建立1001号关键点,坐标为(0,outlet_h,0)
A,1001,13,17    !连接1001,13,17号关键点生成面
A,1001,17,2    !连接1001,17,2号关键点生成面
A,1001,2,9    !连接1001,2,9号关键点生成面
A,1001,9,13    !连接1001,9,13号关键点生成面
ASEL,S,LOC,Y,outlet_h   !新选面
AMESH,ALL     !划分所有选中的面
!*********将面网格延伸为体网格********
TYPE,2     !设置单元类型为2号单元
MAT,2     !设置材料类型为2号材料
EXTOPT,ESIZE,40    !设置延伸份数40
VEXT,ALL,,,,low_h    !设置X,Y,Z方向延伸长度0,low_h,0
EXTOPT,ESIZE,12    !设置延伸份数12
EXTOPT,ACLEAR,1    !设置延伸后去掉面网格
ASEL,S,LOC,Y,outlet_h   !新选择面
VEXT,ALL,,,,-outlet_h,,1/3,,1/3 !设置X,Y,Z方向延伸长度0,-outlet_h,0,延伸比率1/3,0,1/3
ALLS     !选中所有的元素
NUMMRG,ALL    !合并所有重合元素
NUMCMP,ALL    !压缩所有元素的编号
ASEL,S,AREA,,17,20,1   !以增量1选择17到20面
ASEL,INVE     !反选面
AREVERSE,ALL    !反转面的方向
!**************施加约束***************
NSEL,S,LOC,Y,outlet_h-qun_h   !选择裙支座节点
D,ALL,UX     !约束所选节点X方向自由度
D,ALL,UY     !约束所选节点Y方向自由度
D,ALL,UZ     !约束所选节点Z方向自由度
ALLS     !选中所有的元素
EPLOT     !显示单元
/VIEW,1,1,1,1    !正等轴视图
SAVE,MODEL,DB,,MODEL   !保存模型
*END     !结束宏文件
TOWER     !运行宏生成模型
FINI     !退出前处理器
!**************加载与求解****************
/SOLU
ANTYPE,2     !设置分析类型为模态分析
MODOPT,SUBSP,10    !设置模态分析方法为subspace法
MXPAND,10,,,1    !设置模态分析扩展10阶
LUMPM,ON     !打开
ACEL,0,9.8,0    !设置重力加速度
ALLS     !选中所有的元素
SOLVE     !求解
SAVE     !保存
FINI     !退出SOLU求解器
!***************后处理****************
/POST1
FILE,'E411','rst'    !读入结果文件
SET,LIST     !列出各阶频率
SET,1,1     !读取第1阶振型
PLDI     !显示第1阶变形
ANMODE,10,0.5,,0    !制作第1阶动画
SET,1,3     !读取第2阶振型
PLDI     !显示第2阶变形
ANMODE,10,0.5,,0    !制作第2阶动画
SET,1,5     !读取第3阶振型
PLDI     !显示第3阶变形
ANMODE,10,0.5,,0    !制作第3阶动画
SET,1,7     !读取第5阶振型
PLDI     !显示第5阶变形
ANMODE,10,0.5,,0    !制作第5阶动画