fini
/clear
!（1）创建物理环境
/COM, Structural                                 ! 指定结构分析
/TITLE, Tunnel Construct Modeling Analysis       ! 定义工作标题
/FILNAM,support,1                                ! 定义工作文件名
!（2）建立模型
!进入前处理器
/PREP7
!定义分析参数
*set,jd_s ,0       
*set,jd_e,180-jd_s
*set,num,30  
*set,jd ,(jd_e-jd_s)/num    
*set,distance,10                                !溶洞与隧道距离
*set,depth ,80                                  !隧道埋深
*set,fricangle , 37
*set,dens,2200
*set,d,12.8
*set,cohesion,0.6E6
*set,posionratio,0.32
*set,elasticmoduli,3.6E9
*set,t1,0.25 
*set,r_karst,3.6                                !溶洞半径
*set,r1,2.5E-2
*afun,deg
!定义单元类型
ET,1,BEAM3                                       !定义衬砌支护单元
KEYOPT,1,6,1
ET,2,PLANE42                                     !定义围岩单元
KEYOPT,2,3,2
ET,3,LINK1                                       !定义LINK1单元
!定义材料属性
!衬砌支护 
MP,EX,1,2.95E10  
MP,PRXY,1,0.2   
MP,DENS,1,2500
TB,DP,1                                          !采用D-P模型
TBDATA,1,2.42E6,54
!围岩材料
MP,EX,2,3.69E9 
MP,PRXY,2,0.32   
MP,DENS,2,2200
TB,DP,2
TBDATA,1,0.6E6,37
!挖去土体材料
MP,EX,3,3.69E9 
MP,PRXY,3,0.32   
MP,DENS,3,2200
TB,DP,3
TBDATA,1,0.6E6,37
!锚杆
MP,EX,4,17E10 
MP,PRXY,4,0.3   
MP,DENS,4,7960
!定义实常数
R,1,0.3,0.3*0.3*0.3/12,0.3,                        !衬砌支护实常数
R,2,3.14*0.025*0.025/4,,                           !锚杆实常数
!建立几何模型
!创建隧道衬砌支护线
K,1,,,,                                            !创建关键点
K,2,,11.37,,
K,3,3.34,0,,  
K,4,-3.34,0,,
K,201,0,,10, 
K,202,,11.37,10,
K,203,3.34,0,10,  
K,204,-3.34,0,10,
!创建圆
circle,1,5.8,201
circle,2,14.4,202
circle,3,2.67,203
circle,4,2.67,204             
lcsl,all                                           !把四个圆在交点处打断
lsel,s,line,,17,22,1                               !选择线
lsel,a,line,,27,28,1
lsel,a,line,,43
lsel,a,line,,46,48,1
cm,zh,line                                         !定义一个线部件
cmsel,s,zh,line                                    !选择部件
lsel,inve                                          !反选当前的线
ldel,all,,,1                                       !删除所有选择的线
!创建初期支护加固范围
circle,1,8.8,201                                   !画圆
circle,2,17.4,202
circle,3,5.67,203
circle,4,5.67,204
cmsel,s,zh,line                                    !选择线部件
lsel,inve
lcsl,all
lsel,s,line,,5,6,1
lsel,a,line,,31,34,1
lsel,a,line,,37,42,1
lsel,a,line,,44,45,1
lsel,a,line,,49,58,1
lsel,a,line,,60,61,1
lsel,a,line,,64,65,1
ldel,all,,,1
allsel
!绘制溶洞
CYL4,0,-12.8,3.6                                   !绘制圆实体
!细分隧道分析线模型
k,60,-52,-65                                       !创建关键点
k,61,-12,-65
k,62,12,-65
k,63,52,-65
k,64,52,-17.6
k,65,12,-17.6
k,66,-12,-17.6
k,67,-52,-17.6
k,68,-52,-8
k,69,-12,-8
k,70,12,-8
k,71,52,-8
k,72,52,10
k,73,12,10
k,74,-12,10
k,75,-52,10
k,76,-52,80
k,77,-12,80
k,78,12,80
k,79,52,80
l,60,61                                            !连接关键点60、61生成直线
l,61,62
l,62,63
l,63,64
l,64,65
l,65,66
l,66,67
l,67,68
l,68,69
l,69,70
l,70,71
l,71,72
l,72,73
l,73,74
l,74,75
l,75,76
l,76,77
l,77,78
l,78,79
l,79,72
l,78,73
l,77,74
l,75,68
l,74,69
l,73,70
l,71,64
l,70,65
l,69,66
l,67,60
l,66,61
l,65,62
a,60,63,79,76                                      !通过4个关键点生成一个面积区域
asbl,all,all                                       !通过线分割面生成新面
adele,1                                            !删除面
NUMCMP,AREA                                        !压缩面编号
!生成锚杆
asel,s,,,14                                        !选择面14
csys,1                                             !激活柱坐标系
wprota,,-90                                        !工作平面绕X轴旋转-90度
*do,i,1,30,1                                       !循环控制
wprota,,,-6                                        !工作平面绕Y轴旋转-6度
asbw,all                                           !用工作平面切割所选择的所有面
*enddo
asel,s,,,14,15,1                                   !选择面
asel,a,,,19,20,1
asel,a,,,22,25,3
asel,a,,,26,28,2
asel,a,,,31,32,1
asel,a,,,34,50,2
asel,a,,,53,54,1
asel,a,,,56,59,3
asel,a,,,60,62,2
asel,a,,,65,67,1
asel,a,,,69,71,2
asel,a,,,75
aadd,all                                           !删除所选择的所有面
allsel
!保存几何模型
!save,Tunel-geom.db
!划分网格生成有限元模型
!划分梁单元
mat,1                                              !指定梁单元材料特性
type,1
asel,s,,,11
lsla,s,
esize,1                                            !指定划分梁单元长度
lmesh,all                                          !划分所有线
allsel
!划分锚杆
lsel,s,,,26,48,22                                  !选择锚杆线
lsel,a,,,61,71,10
lsel,a,,,77,89,12
lsel,a,,,92,95,3
lsel,a,,,107,113,3
lsel,a,,,125,131,6
lsel,a,,,137,139,2
lsel,a,,,143,151,8
lsel,a,,,157,169,6
lsel,a,,,172,175,3
lsel,a,,,187,193,3
lsel,a,,,205,211,3
lsel,a,,,212,213,1
mat,4                                              !指定锚杆单元材料特性
type,3
lmesh,all
allsel
!划分开挖掉土体单元网格
mat,3
type,2
mshkey,0                                           !设定自由网格划分
mshape,0                                           !设定四边形网格划分
esize,
amesh,11                                           !划分11号面
!划分围岩网格
!设置网格份数
lsel,s,,,5,11,1                                    !选择线
lsel,a,,,13,15,1
lsel,a,,,31,33,1
lsel,a,,,37,39,1
lsel,a,,,53,55,1
lesize,all,,,6                                     !把所选择线分为6份
lsel,s,,,1,4,1
lsel,a,,,50,52,1
lsel,a,,,12
lesize,all,,,4                                     !把所选择线分为4份
lsel,s,,,16,34,18
lsel,a,,,40,42,1
lsel,a,,,44,45,1
lsel,a,,,49
lesize,all,,,8                                     !把所选择线分为8份
mat,3                                              !赋予围岩单元属性
type,2
mshkey,0                                           !设定自由网格划分
mshape,0                                           !设定四边形网格划分
allsel
asel,s,,,11                                        !选择面11
asel,inve                                          !反选当前面
amesh,all                                          !划分所有面
allsel
!保存网格模型
!save,Tunel-grid.db
（3）施加约束和荷载
!施加约束
csys,0
nsel,s,loc,x,-52                                   !选择X=-52线上所有节点
nsel,a,loc,x,52                                    !选择X=52线上所有节点
d,all,ux                                           !对所选择节点约束X方向位移
allsel
nsel,s,loc,y,-65                                   !选择Y=--65线上所有节点
d,all,uy                                           !对所选择节点约束Y方向位移
!施加重力加速度
acel,,9.8
（4）求解
/solu
!求解设置
antype,static                                      !设定为静力求解
nsubst,100                                         !设定最大子步数为100
pred,on                                            !打开时间步长预测器
nropt,full                                         !设定牛顿-拉普森选项
nlgeom,on                                          !打开大位移效果
lnsrch,on                                          !打开线性搜索
outres,all,all                                     !输出所有项
cnvtol,f,,0.02,2,0.5                               !力收敛准则设定
cnvtol,m,,0.01,2,1                                 !力矩收敛准则设定
!初始应力模拟
time,1                                             !设定载荷步结束时间
allsel
esel,s,mat,,1,4,3                                  !选择材料号为1、4的单元
ekill,all                                          !杀死所选择的单元
esel,all
esel,s,live                                        !选择活单元
nsle,s                                             !选择节点
nsel,inve                                          !反选择当前节点
d,all,all                                          !约束所选择节点、自由度
allsel
solve                                              !求解
save,tunnel-step1,db                               !把初始应力模拟求解结果保存
!隧道开挖与支护模拟
allsel
time,2                                             !设定载荷步结束时间
esel,s,mat,,3                                      !开挖
ekill,all                                          !杀死挖去土体单元
esel,s,mat,,1,4,3                                  !支护
ealive,all                                         !激活支护单元
nsle,s
ddele,all,all                                      !删除位移约束
esel,all
esel,s,live                                        !选择活单元
nsle,s
nsel,inve
d,all,all,0                                        !约束非活动节点
nsel,all
esel,all
solve                                              !求解
save,Tunel-step2,db                                !把开挖模拟求解结果保存
!列车荷载模拟
time,3                                             !设定载荷步结束时间
f,6,fy,-525000                                     !施加集中力
f,41,fy,-525000
allsel
solve                                              !求解
save,Tunel-step3,db                                !把列车模拟求解结果保存
（5）后处理
/post1
!初始应力模拟结果分析
Resume,'tunnel-step1','db'                         !读入初始应力模拟数据
set,1,last                                         !读入本荷载步最后一个子步
esel,s,live                                        !选择活单元
!显示位移云图
plnsol,u,sum,                                      !绘制总位移矢量云图
plnsol,u,x                                         !绘制X方向位移云图
plnsol,u,y                                         !绘制Y方向位移云图
!显示应力云图
plnsol,s,x                                         !绘制X方向应力云图
plnsol,s,y                                         !绘制Y方向应力云图
plnsol,s,z                                         !绘制Z方向应力云图
plnsol,s,1                                         !绘制第1主应力云图
plnsol,s,2                                         !绘制第2主应力云图
plnsol,s,3                                         !绘制第3主应力云图
plnsol,s,eqv                                       !绘制等效应力云图
!开挖模拟结果分析
Resume,'tunnel-step2','db'                         !读入开挖模拟数据
set,1,last                                         !读入本荷载步最后一个子步
esel,s,live
!显示位移云图
plnsol,u,sum,                                      !绘制总位移矢量云图
plnsol,u,x                                         !绘制X方向位移云图
plnsol,u,y
!显示应力云图
plnsol,s,x                                         !绘制X方向应力云图
plnsol,s,y                                         !绘制Y方向应力云图
plnsol,s,z
plnsol,s,1
plnsol,s,2                                         !绘制第2主应力云图
plnsol,s,3
plnsol,s,eqv                                       !绘制等效应力云图
!显示梁支护内力
esel,s,mat,,1                                      !选择材料号为1的单元
etable,IMOMEMT,SMISC,6                             !定义弯矩表
etable,JMOMEMT,SMISC,12                       
etable,ISHEAR,SMISC,2                              !定义剪力表
etable,JSHEAR,SMISC,8
etable,ZHOULI-I,SMISC,1                            !定义轴力表
etable,ZHOULI-I,SMISC,7
/TITLE,BENDING MOMENT distribution                 !定义弯矩分布标题
PLLS,IMOMEMT,JMOMEMT,-0.5                          !绘制弯矩分布图
/TITLE,SHEAR force distribution                    !定义剪力分布标题
PLLS,ISHEAR,JSHEART,0.5                            !绘制剪力分布图
/TITLE,ZHOULI force distribution                   !定义轴力分布标题
PLLS,ZHOULI-I,ZHOULI-J,0.1                         !绘制轴力分布图
!显示锚杆内力
esel,s,mat,,4                                      !选择材料号为4的单元
etable,ZHOUYINBIAN,LEPEL,1                         !定义轴应变表
etable,ZHOUL,SMISC,1                               !定义轴力表
/TITLE,ZHOUYINBIAN distribution                    !定义轴应变分布标题
PLLS,ZHOULI,ZHOULI,0.05                            !绘制轴力分布图
PLLS,ZHOUYINBIAN,ZHOUYINBIAN,0.05                  !绘制轴应变分布图
!列车荷载模拟结果分析
Resume,'tunnel-step3','db'                         !恢复列车荷载模拟结果
set,1,last                                         !读入本荷载步最后一个子步
esel,s,live
!显示位移云图
plnsol,u,sum,                                      !绘制总位移矢量云图
plnsol,u,x                                         !绘制X方向位移云图
plnsol,u,y                                         !绘制Y方向位移云图
!显示应力云图
plnsol,s,x                                         !绘制X方向应力云图
plnsol,s,y                                         !绘制Y方向应力云图
plnsol,s,z                                         !绘制Z方向应力云图
plnsol,s,1                                         !绘制第1主应力云图
plnsol,s,2                                         !绘制第2主应力云图
plnsol,s,3                                         !绘制第3主应力云图
plnsol,s,eqv                                       !绘制等效应力云图
!显示梁支护内力
esel,s,mat,,1
etable,IMOMEMT,SMISC,6                             !定义弯矩表
etable,JMOMEMT,SMISC,12
etable,ISHEAR,SMISC,2                              !定义剪力表
etable,JSHEAR,SMISC,8
etable,ZHOULI-I,SMISC,1                            !定义轴力表
etable,ZHOULI-I,SMISC,7
/TITLE,BENDING MOMENT distribution                 !定义弯矩分布标题
PLLS,IMOMEMT,JMOMEMT,-0.5                          !绘制弯矩分布图
/TITLE,SHEAR force distribution
PLLS,ISHEAR,JSHEART,0.5                            !绘制剪力分布图
/TITLE,ZHOULI force distribution
PLLS,ZHOULI-I,ZHOULI-J,0.1                         !绘制轴力分布图
!显示锚杆内力
esel,s,mat,,4
etable,ZHOUYINBIAN,LEPEL,1                         !定义轴应变表
etable,ZHOUL,SMISC,1                               !定义轴力表
/TITLE,ZHOUYINBIAN distribution         
PLLS,ZHOULI,ZHOULI,0.05                            !绘制轴力分布图
PLLS,ZHOUYINBIAN,ZHOUYINBIAN,0.05                  !绘制轴应变分布图