原文网址：http://blog.sciencenet.cn/blog-456941-521389.html

应力刚化　stress stiffening

    举个例子，比如一根杆，受到轴向拉压力，其自身的横向刚度会随拉压力的变化而变化，拉力会增加横向刚度，而压力会减小横向刚度。拉力越大，横向刚度越大，导致横向振动的固有频率提高。比如，小提琴的弦，崩得越紧即轴向拉力越大，则听起来音值越高，即是横向振动固有频率提高了。再比如，一面鼓的鼓面，当它绷紧时会产生垂向刚度，这也是应力刚化的典型例子。

内应力和横向刚度之间的联系通称为应力刚化。应力刚化是指构件在无应力状态和有应力状态下的刚度变化，在有应力状态下，构件某方向的刚度显著增大。比如悬索桥主缆或斜拉桥的拉索在未加轴向拉力时，其横向刚度几乎为零；但是在受到很大拉力作用的时候，其横向刚度显著变大，这就是应力刚化效应。

ANSYS程序通过生成和使用一个称为应力刚化矩阵的辅助刚度矩阵来考虑应力刚化效应，尽管应力刚度矩阵是使用线性理论得到的，但由于应力（应力刚度矩阵）在每次迭代之间是变化的这个事实，因而它是非线性的。大变形分析中(NLGEOM,ON)包含应力刚化效应（SSTIF,ON），将把应力刚度矩阵加到主刚度矩阵上，以便在具有大应变或大挠度性能的大多数单元中产生一个近似的协调切向刚度矩阵。

ANSYS的非线性分析中，应力松弛效应是什么意思？

应力松弛　stress relaxation

　　粘弹性材料在总应变不变的条件下，由于试样内部的粘性应变(或粘塑性应变)分量随时间不断增长，使回弹应变分量随时间逐渐降低，从而导致变形恢复力（回弹应力）随时间逐渐降低的现象。测定应力松弛曲线是测定松弛模量的实验基础。高温下的紧固零件，其内部的弹性预紧应力随时间衰减，会造成密封泄漏或松脱事故。松弛过程也会引起超静定结构（见结构力学）中内力随时间重新分布。用振动法消除残余应力就是设法加速松弛过程，以便消除材料微结构变形不协调引起的内应力。使流动的粘弹性流体速度梯度减小或突然降为零，流体中的应力逐渐降低或消失的过程也称为应力松弛。

　　应力松弛现象：打包带变松、橡皮筋变松

作者拾人牙慧，先贴几个例子，然后再跟大家讨论，由于论坛上的帖子太多，这几个例子也无从查找，到底是谁的作品，哪位如有意见可告知作者，届时说明出处：

简化模拟悬索桥主缆在重力作用下的变形：

/PREP7 
!定义主缆节点 
!Back side nodes of Cable 
k,  1,   -58.319,   8.120,      0 
k,  2,   -50,      11.432,      0 
k,  3,   -45,      13.882,      0 
k,  4,   -40,      16.742,      0 
k,  5,    -35,     20.08,       0 
k,  6,   -30,      17.650,      0 
k,  7,   -25,      15.629,      0 
k,  8,   -20,      13.977,      0 
k,  9,   -15,      12.691,      0 
k, 10,   -10,      11.772,      0 
k, 11,   -5,       11.221,      0 
k, 12,   0,        11.038,      0 
k, 13,   5,        11.221,      0 
k, 14,   10,       11.772,      0 
k, 15,   15,       12.691,      0 
k, 16,   20,       13.977,      0 
k, 17,   25,       15.629,      0 
k, 18,   30,       17.650,      0 
k,  19,   35,     20.08,       0 
k, 20,   40,       16.742,      0 
k, 21,   45,       13.882,      0 
k, 22,   50,       11.432,      0 
k, 23,   58.319,    8.120,      0 
!生成主缆单元 
ET,1,LINK10 
MP,EX  ,  1  ,  2.00E+11 
MP,NUXY  ,  1  ,  0.3333 
MP,DENS  ,  1  ,  7850 
MP,ALPX  ,  1  ,  1.20E-05 
R,1,0.01,1.0e-8 
TYPE,1 
MAT,1 
REAL,1 
*do, i, 1, 22,1 
  l,i,i+1        
*enddo   
ESIZE, , 1 
lmesh,all 
DK, 1, all 
dk,23,all 
DK, 5, uy 
dk,19,uy 
ACEL,,9.81  
/SOLU    
ANTYPE,0 
NLGEOM,1 
!NROPT,AUTO, ,    
!LUMPM,0  
!EQSLV, , ,0, 
!PRECISION,0  
!MSAVE,0  
!PIVCHECK,1   
SSTIF,ON 
!TOFFST,0,    
!PSTRES,0 
SOLVE    
FINISH  !应变为0的话，不能计算，在0.001情况下，就可以计算

做索的模拟，单元可以选择link10，它为单向受压或受拉单元；在土木工程中，一般索单元都只承受拉力。索单元的结构在计算时，有时比较难收敛，经常出现‘位移超过一定的限制’这个错误。现在以悬索桥主缆为例，说明一下索单元的计算技巧，有一个很重要的是建议设置keyopt（2）=1或2，这样设置后，他认为当索松弛时，索单元还将具有很小的横向刚度，这样的话更加符合实际情况，可以计算索由松到紧这个过程，否则会出现上面所提到的错误；另外，为了收敛建议给索单元初应变（对于实际索无初应变的情况，可以把你设置的初应变数值定位很小1e-8），这样对计算结果不会有影响，并且可以加速收敛；对于索单元，一般为大位移小变形结构，加以nlgeom和sstif均设置为on。

本文作者简评：

我不知道这个例子的作者有没有很清楚link10的用法，反正本文作者在使用link10单元的过程发现，无论是否设置keyopt（2）=1或2，对结果都没有多大的影响。

比如，你做斜拉桥拉索模拟，一根斜拉索只要是划分成一个单元，换言之斜拉索中间不能有节点，这时候计算顺利进行。而如果，你要试图对一根斜拉索划分成多段单元，是不可能计算下去的，无论是是否设置keyopt（2）=1或2以使索松弛时，索单元还将具有很小的横向刚度都会出现‘位移过大，计算终止’的情景。

对于千米级斜拉桥，有人已经提出弹性模量的折减的方法对结构的反应，尤其是主塔位移响应等，计算结果误差过大；建议使用悬链线等单端划分单元的方法进行计算。

本文作者计算经验和计算结果显示，ANSYS不能依靠link10单元实现这个目的。因此，我对这个例子仅对link10能否算出拉索或主缆的变形很怀疑。因为大家只要仔细看一下link10的说明就会发现，link10的建立正式基于弹性模量折减这个理论基础建立起来的单元，你怎么让它去实现多段划分单元以按照悬链线理论去计算拉索这种柔性结构的变形呢？

下面是一道用ANSYS进行悬索结构的找形和计算的例题：

/prep7  
ET,1,LINK10  
!找形时采用很小的弹性模量  
R,1,0.001468,0.9,  
MP,EX,1,0.60551e9  
MP,NUXY,1,0.3  
!定义节点  
*do,i,1,5  
*do,j,1,2*i-1  
k=(i-1)*(i-1)+j  
n,k,(j-i)*9.15,-36.6+(i-1)*9.15,0  
*enddo  
*enddo  
*do,i,1,4  
*do,j,1,2*i-1  
k=(i-1)*(i-1)+j+25  
n,k,(j-i)*9.15,36.6-(i-1)*9.15,0  
*enddo  
*enddo  
!定义单元  
*do,i,1,4  
*do,j,1,2*i  
k=i*i+j  
e,k,k+1  
*enddo  
*enddo  
*do,i,1,3  
*do,j,1,2*i  
k=i*i+j+25  
e,k,k+1  
*enddo  
*enddo  
*do,i,1,4  
*do,j,1,2*i-1  
k=(i-1)*(i-1)+j  
e,k,k+2*i  
*enddo  
*enddo  
*do,i,1,3  
*do,j,1,2*i-1  
k=(i-1)*(i-1)+j+25  
e,k,k+2*i  
*enddo  
*enddo  
*do,i,18,24  
e,i,i+17  
*enddo  
!施加位移约束  
d,1,ux,0  
d,1,uy,0  
d,1,uz,3.66  
d,2,ux,0  
d,2,uy,0  
d,2,uz,1.83  
d,4,ux,0  
d,4,uy,0  
d,4,uz,1.83  
d,5,ux,0  
d,5,uy,0  
d,5,uz,0  
d,9,ux,0  
d,9,uy,0  
d,9,uz,0  
d,10,ux,0  
d,10,uy,0  
d,10,uz,-1.83  
d,16,ux,0  
d,16,uy,0  
d,16,uz,-1.83  
d,17,ux,0  
d,17,uy,0  
d,17,uz,-3.66  
d,25,ux,0  
d,25,uy,0  
d,25,uz,-3.66  
d,35,ux,0  
d,35,uy,0  
d,35,uz,-1.83  
d,41,ux,0  
d,41,uy,0  
d,41,uz,-1.83  
d,30,ux,0  
d,30,uy,0  
d,30,uz,0  
d,34,ux,0  
d,34,uy,0  
d,34,uz,0  
d,27,ux,0  
d,27,uy,0  
d,27,uz,1.83  
d,29,ux,0  
d,29,uy,0  
d,29,uz,1.83  
d,26,ux,0  
d,26,uy,0  
d,26,uz,3.66  
!设定时间步  
TIME,1  
AUTOTS,0  
NSUBST,20, , ,1  
KBC,0  
!输出每个子步的结果  
OUTPR,BASIC,ALL,  
OUTRES,ALL,ALL,  
!设定大变形，应力刚化  
NLGEOM,1  
SSTIF,ON  
FINISH  
!求截  
/SOLU  
/STATUS,SOLU  
SOLVE  
FINISH  
!后处理  
/POST1  
PRNSOL,DOF,  
PRESOL,SMISC,1  
PLESOL,SMISC,1  
PLNSOL,U,X,0,1  
finish  
/PREP7  
!更新几何形状  
!a.rst为计算结果文件名，最后一个为目录  
!这两个参数应根据你的计算情况定  
UPGEOM,1,LAST,LAST,a,rst,E:\JZD\1\  
!弹性模量恢复为真值  
R,1,0.001468,0.0027248,  
MP,EX,1,2.0e11  
!重新施加位移约束  
d,1,uz,0  
d,2,uz,0  
d,4,uz,0  
d,5,uz,0  
d,9,uz,0  
d,10,uz,0  
d,16,uz,0  
d,17,uz,0  
d,25,uz,0  
d,35,uz,0  
d,41,uz,0  
d,30,uz,0  
d,34,uz,0  
d,27,uz,0  
d,29,uz,0  
d,26,uz,0  
!求截  
/SOLU  
/STATUS,SOLU  
SOLVE  
FINISH  
/POST1  
!观察施加荷载之前结构的位移  
!可见位移基本为零,预张力基本不变  
PLNSOL,U,Z,0,1  
PLESOL,SMISC,1  
FINISH  
!写荷载工况文件01  
/PREP7  
LSWRITE,01,  
!施加节点荷载  
*do,i,1,41  
f,i,fz,-167445  
*enddo  
!设置第2荷载步  
TIME,2  
AUTOTS,0  
NSUBST,20, , ,1  
KBC,0  
LSWRITE,02,  
!求解  
FINISH  
/SOLU  
LSSOLVE,1,2,1,  
后处理   
/POST26  
!可以看到，该结果和书中结果一致  
NSOL,2,21,U,Z,  
PLVAR,2, , , , , , , , , ,  
ESOL,3,33,1,F,Y,  
PLVAR,3, , , , , , , , , ,  

本文作者简评：这个例子是利用link10对主缆找形