加载中…
个人资料
凡人sypls
凡人sypls
  • 博客等级:
  • 博客积分:0
  • 博客访问:585,769
  • 关注人气:514
  • 获赠金笔:0支
  • 赠出金笔:0支
  • 荣誉徽章:
相关博文
推荐博文
谁看过这篇博文
加载中…
正文 字体大小:

通达信公式教程(四)《快速改写选股指标与优化》

(2012-03-16 16:32:25)
标签:

杂谈

分类: 通达信使用知识

第五讲:各种形态的描述

  懂得运用公式编辑器,掌握了公式的基本函数,就可以进行简单的公式编写了。下面我们共同认识一下公式的基本语句。这些基本语句,是编写公式和整理选股公式信号的基础,大家要熟知。                    

一、K线的基本形态

  1、当天收阳:CLOSE>OPEN;

  2、当天收阴:CLOSE<OPEN;

  3、当天股价高开,言下之意开盘高于昨日收盘:OPEN>REF(CLOSE,1);

  4、当天股价低开:OPEN<REF(CLOSE,1);

  5、跳空高开:OPEN>REF(HIGH,1);当日开盘在昨日最高价之上

  6、跳空低开:POEN<REF(LOW,1);

  7、长阳:C/O>1.03 或者 (C-O)/O*100>5 或者 (C-O)/O>0.05 意思是收盘价比开盘价上涨5%以上。当然,用7%以上也可。

  8、长阴:C/O<0.94; 注意:同一语句可有多种表述,此为其一。

  9、高开大阴:O/REF(C,1)>1.04  AND C/O<1.94; 今天开盘比昨天收盘高出4%和收盘价较开盘下降6%。低开大阳与此正好相反。

  10、标准十字星:CLOSE=OPEN AND HIGH<>LOW

  更多见的是近似十字星。例:ABS(C-O)<0.02 AND H-C>0.03 AND C-L>0.03; 该语句用上了一个函数:ABS,意思是求绝对值。这样,该近似十字星即可能是阳星也可能是阴星。

  再认识两个函数:MAX(A,B) 求A和B中的最大值。

          MIN(A,B) 求A和B中的较小值

  有了这两个函数,近似十字星还可这样表述:ABS(C-O)<0.02 AND H> MAX(C,O) AND L< MIN(C,O);

  另外,该公式还可以用比例数编写。

  11、长下影线:也有收阴收阳之分。以阳线长下影线为例:C>O AND (O-L)>(C-O);此公式只表达了下影线比实体线长,并没有表达长度比例和有无上影线。

  留个习题吧:不限制阴阳线,上影小于5分钱,下影线是实体的两倍以上。

  形态还有许多,有几十种,不一一例举了,大家举一反三,慢慢摸索吧。

二、条件选股的基本形态

  1、阶段最高价:HHV(H,N) 意思是取得N天之内的最高价。新函数:HHV,最高值。

  2、阶段最低价:LLV(L,N)意思是取得N天之内的最低价。新函数:LLV,最低值。

  3、阶段涨幅 (C-REF(C,N))/REF(C,N)*100 N日收盘价的差值的百分比。

  4、再创新高 HIGH=HHV(HIGH,N) 是指今日最高价是N日以来的最高价.。再创新低:略。

  5、放量:

  (1)今日比昨日的成交量放大了1倍: VOL/REF(VOL,1)>2;

  (2)今日的五日均量比前五天的五日均量放大了3倍:

  AA:=MA(VOL,5);

  BB:=REF(AA,5);

  AA/BB>4;

  (3)今天的成交量达到了整个流通盘的10%以上: VOL/CAPITAL>10/100;

  注意,10%的表达式是10/100,或者0.1

  6、缩量:

  (1)今日比昨日的成交量缩小了1倍: VOL/REF(VOL,1)<0.5;

  (2)今日的五日均量比前五天的五日均量缩小了一半:

  AA:=MA(VOL,1)<0.5;

  BB:=REF(AA,5);

  AA/BB<0.5;

  (3)今天的成交量不足整个流通盘的0.5%: VOL/CAPITAL<0.5/100;

  7、放量上攻  是指价格上扬,成交量剧增

  C/REF(C,5)>1.2 AND VOL>MA(VOL,5)*3; 表示5日上涨20%和成交量超过5日均量的3倍。

  8、持续放量:COUNT(V>REF(V,1),N)=N; 实际上这种情况不是很多。如果用3日均量,或5日均量则非常普遍。即:COUNT(MA(V,3)>REF(MA(V,3),1),N)=N;

  9、阶段放量

  N(1,100,10)  M(1,100,5)

  SUM(VOL,N1)/CAPITAL>=(N/100)  M日内换手率大于百分之N

  10、温和放量上攻

  M(2,10,3) N(1,40,10)

  UP:=MAX(C,O)>REF(MAX(C,O),1);

  A:=VOL>REF(VOL,1);

  COUNT(IF((UP AND A),1,0),N)=N AND C>O

  AND (C-REF(MAX(C,OPEN),1))/REF(MAX(O,C),1)<=(3/100)

  AND VOL/CAPITAL<=(M/100)

  连续N个周期放大并保持上涨势头 当日换手率小于 M%

  11、突然放量

  N(1,300,10)M(1,40,3)

  VOL>REF(HHV(VOL,N),1)*M

  成交量较前N周期的最大成交量增大M倍

  12、上涨: C/REF(C,1)>1.07;今日涨幅达到了7%以上。

  注意:涨幅是指当天收盘价与昨天的收盘价之比。

  13、下跌:同上面的表达方式一样,将方向改变了而已。

  14、十日均价继续上涨:

  AA:=MA(C,10);

  BB:=REF(AA,1);

  AA>BB;

  15、窄幅整理:就是指近一段时期价格维持在一定幅度之内  

  (HHV(C,20)-LLV(C,20))/C<0.08 ;即20日内价格振幅在8%以内波动。

  16、连续N天收阳:COUNT(C>O,N)=N; 

    特别提示:新函数:COUNT(X,N),统计满足条件的周期数。若N=0则从第一个有效值开始。

例:COUNT(C<O,10) 表示统计10周期内收阴的周期数。此句使用时必须加上条件,即收阴时怎么了方才有效。如:AA AND COUNT(C<O,10) 的返回值仍是AA,只有AA AND COUNT(C<O,10)<=3;时,即加上条件“小于等于3”周期时,才有实际意义。这个函数经常用到,务请留意。

  17、N日内阳线多于阴线:COUNT(C>O,N)>N/2; 

  18、创历史新高:C=HHV(C,0); 

  特别提示:此公式本应为:C=HHV(C,N); 当N等于0时,从第一天开始统计。统计历史数据时,如果从头开始,都用0。

  19、尾盘拉升

  HOUR>14 AND MINUTE>56 AND CLOSE/REF(CLOSE,2) >= 1+N/100

  14:56以后2分钟涨幅超过N%

  20、突破长期盘整

  N(10,60,30)  M(5,50,30)

  REF(((HHV(H,N)-LLV(L,N))/LLV(L,N)),1)<=(M/100)AND C>=REF(HHV(H,N),1) AND BARSCOUNT(C)>N

  前N日在上下M%的幅度内整理,今日突破。

 

21、阶段强势股

  N(700101,1341231,990519) M(700101,1341231,990913)

  A:=SUM(IF(DATE-N=0,INDEXC,0),0);

  B:=SUM(IF(DATE-M=0,INDEXC,0),0);

  E:=SUM(IF(DATE-N=0,C,0),0);

  F:=SUM(IF(DATE-M=0,C,0),0);

  ((F-E)/E)>((B-A)/A)

  选择N日----M日之间内走势强于大盘的股票.

  22、大盘同步选股

  N(1,100,10)M(1,100,50)

  COUNT((C>O AND INDEXC>INDEXO) OR (C< AND INDEXC< INDEXO),N)/N M/100

  N周期中与大盘走势相同(同收阴线或同收阳线)的比例超过M%

   23、今收盘对于N日内最低收盘价的涨幅(%)

  (C-LLV(C,N))/LLV(C,N)*100;

  24、今收盘对于N日内最高收盘价的跌幅(%)

  (HHV(C,N)-C)/HHV(C,N)*100;

   25、股价在过去N日内运行空间的相对位置

  (C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;  

  26、股价上方N1%至N2%处的筹码(%)

  AA:=WINNER(C+C*N2/100)*100;

  BB:=WINNER(C+C*N1/100)*100;

  AA-BB

  认识新函数:WINNER(CLOSE) 获利盘比例。表示以当前收市价卖出的获利盘比例,如返回0.2表示20%获利盘;例如:WINNER(10) 表示10元价格的获利盘比例。该函数仅对比较日线分析周期有效。  

  27、股价下方N1%至N2%处的筹码(%)

  (WINNER(C-C*N1/100)-WINNER(C-C*N2/100))*100;

  28、收盘价N%处的套牢盘

       100-(WINNER(C*N/100))*100;

  29、收盘价N%处的获利盘

WINNER(C*N/100)*100;

 

三、基本面选股举例

  1、小盘选股

  CAPITAL<=500000 AND FINANCE(33)>=0.01 AND CLOSE<=30

  2、低市盈率选股

  DYNAINFO(39)<=N AND DYNAINFO(39)>0

  3、业绩选股

  N(0,100,0.4)

  FINANCE(33)>N 每股收益在0.4元以上

  4、小盘股

  N:=5000;

  FINANCE(7)<=N

  5、大盘股

  N:=20000;

  FINANCE(7)>=N

  6、净资产收益率选股

  FINANCE(37)>(N/100) 净资产收益率高于N的股票

  7、每股净资产选股

  FINANCE(34)>N 选出每股净资产大于N元的股票.

  8、每股未分配利润选股

  FINANCE(32)>N 每股未分配利润大于N的股票

  9、市净率选股

  C/FINANCE(34)< N

  市净率=市价/每股净资产  市净率>N

  市净率越低公司股价越有被低估的可能,这类股票从理论上讲具有更高的安全性.

  10、换手率选股

  DYNAINFO(37)>=N/100 单日换手率大于N的股票

  换手率的计算公式或表达式:VOL/CAPITAL*100; 因此也可写作:VOL/CAPITAL*100>=N/100

      11、掁幅:(H-L)/REF(C,1)*100; 注意:是比的昨天收盘价。

天天★学习

问个菜鸟问题:压缩后的公式,解压后成了FNC文件,请问楼主怎么加到公式管理器里去?

FNC是大智慧2和分析家格式,只有这两个股软能够导入。导入的方法是:打开公式编辑器,点击导入---找到存放此公式的文件夹---双击---在出现的列表中掸单击该公式---选导入。

特别提示:必须先将公式存放在一个文件夹中,已有的,新建都可以。否则编辑器无法找到该公式。

淡定笑人生

习题:不限制阴阳线,上影小于5分钱,下影线是实体的两倍以上

不懂何谓5分线,无法做习题!

按自己理解的意思做出来:

(H-O)/O<0.05 AND MIN((C-L),(O-L))/ABS(C-O)>=2

方方面面2008

交作业:不限制阴阳线,上影小于5分钱,下影线是实体的两倍以上。

A:=c>0 AND H-C<0.05 AND (O-L)/(C-O)>2;

B:=C<0 AND H-O<0.05 AND (C-L)/(O-C)>2;

OR B

可能大家不知道,

当初对于大智慧1中不能用英文表示颜色只能用6位16进制代码的表示,我曾专门对照查找过的,很费时间,

也就是说老杨写的几个字都是用大量时间精力换来的,来之不易,

希望大家好好学习。

这里我转几个针对线性和颜色函数方面的公式实例,做个参考吧。是原来五行鼠的帖子,这人很久不来了。

1间隔点:

20,colorred,pointdot,linethick2;

80,colorred,pointdot,linethick2;

50,colorred,pointdot,linethick2;

2间隔线

20,colorred,linethick2;

80,colorred,linethick2;

50,colorred,linethick2;

3信号字

DRAWTEXT(RSI1<10,RSI1,''买''),Colorlime;

DRAWTEXT(RSI1>85,RSI1,''卖''),Colorlime;

4笑哭脸

DRAWICON(VR24<25,VR24,1),ColorFF0000;

DRAWICON(VR24>350,VR24,2),ColorFF0000;

5一线提示

cross("kdj.j"(9,3,3),"kdj.d"(9,3,3)) and "kdj.j"(9,3,3)<20,colorred

6一柱顶天

IF(VAR4=50,50,0),stick,linethick2;

7小人作怪

多头卒:Var3,LINETHICK2, COLORf00ff0;

空头卒:Var4,LINETHICK2, COLORYELLOW;

DRAWICON(Var9,Var9,1);

DRAWICON(Var10,Var10,2);

8小人

买入:Var1 AND Var2,stick,linethick2,colorred;

卖出:CROSS(80,Var4),stick,linethick2,colorgreen;

drawicon(卖出,1.1,2);

drawicon(买入,1.1,1);

9粗细面条

LINETHICK2

第3,4,6和7,还有8只要把RSI或VR或Var改成所在公式参数就可用;第5cross不能改,其它的可改;9你爱把线设多粗细都行。

1方块STICKLINE

AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));

买盘:IF(CLOSE>OPEN,AA*(HIGH-LOW),IF(CLOSE<OPEN,AA*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2));

卖盘:IF(CLOSE>OPEN,0-AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-AA*(HIGH-LOW),0-VOL/2));

qq:=买盘+卖盘;

STICKLINE(卖盘<0,0,VOL,5,1),COLORlime;

STICKLINE(买盘>0,0,买盘,5,0),COLORRED;

结果:ma(qq,5)*5,COLORRED,LINETHICK2;

VOL后面的5,1是方块大少。VOL是坐标,也就是方块所放的地方。

3D效果

STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,9,0 ),COLORaaaaaa;

STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,6,0 ),COLORbbbbbb;

STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,2.4,0 ),COLORcccccc;

STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,1.1,0 ),COLORdddddd;

STICKLINE(CLOSE>OPEN,CLOSE,OPEN,9,0 ),COLOr6666cc;

STICKLINE(CLOSE>OPEN,CLOSE,OPEN,6 ,0 ),COLOR7777dd;

STICKLINE(CLOSE>OPEN,CLOSE,OPEN,2.4 ,0 ),COLOR8888ee;

STICKLINE(CLOSE>OPEN,CLOSE,OPEN,1.1 ,0 ),COLOR9999ff;

STICKLINE(CLOSE>OPEN,OPEN,LOW,0.5,0 ),COLOR1199ff;

STICKLINE(CLOSE>OPEN,CLOSE,HIGH,0.5 ,0 ),COLOR1199ff;

STICKLINE(OPEN>=CLOSE,CLOSE,LOW,0.5 ,0 ),COLORcccccc;

STICKLINE(OPEN>=CLOSE,OPEN,HIGH,0.5 ,0 ),COLORcccccc;

3颜色

大智慧只能用浅色调,一用深绿深蓝就看不见了。所以我调了几个浅色的,够大智慧用的。

COLOR+RED;WHITE;LIME;YELLOW;aabbcc;ffaabb;abcdef;999999;C0C0C0.

4变色

变色可分3种:

1用DRAWTEXT:

ma10:ma(c,10),colorwhite;

llv(h,30),colorffcc66;

llv(l,30),coloryellow;

vhh:hhv(h,30),colorred;

vhl:hhv(l,30),color00ff00;

v1:=ma(HIGH,30)*1.15 ;

v2:=ma(HIGH,3)*1.03;

v3:=ma(LOW,3)*0.97;

v4:=ma(LOW,30)*0.85;

小通道上:=ma(v2,30);

小通道下:=ma(v3,30);

A2:=小通道上-REF(小通道上,1);

A3:=小通道下-REF(小通道下,1);

K:A2>0 and ref(A2<0,1),colorblue;

K1:A3>0 and ref(A3<0,1),colorff00ff;

K2:c<小通道下 and h<小通道下,color0099ff;

K3:c<小通道下 and A3>0,colorffcccc;

K4:h<小通道下 and A3>0,colorffbbff;

DRAWTEXT(A2>0 ,小通道上,''?/SPAN>''),colorred;

DRAWTEXT(A2<0 ,小通道上,''?/SPAN>''),color00ff00;

DRAWTEXT(A3>0 ,小通道下,''?/SPAN>''),colorred;

DRAWTEXT(A3<0 ,小通道下,''?/SPAN>''),color00ff00;

DRAWTEXT(A2=0 ,小通道上,''?/SPAN>''),COLORWHITE;

DRAWTEXT(A2=0 ,小通道下,''?/SPAN>''),COLORWHITE;

DRAWTEXT(A3=0 ,小通道上,''?/SPAN>''),COLORWHITE;

DRAWTEXT(A3=0 ,小通道下,''?/SPAN>''),COLORWHITE;

2用STICKLINE

AA:=WINNER(C)*100;

KA:=winner(O)*100;

高:=winner(H)*100;

低:=winner(L)*100;

庄筹线:EMA(AA*0.7,3),linethick2;

散筹线:EMA((WINNER(C*1.08)-WINNER(C*0.92))*70,3),linethick2;

stickline(AA<KA,高,低,0,0),colorlime;

stickline(AA<KA,AA,KA,6,0),colorlime;

stickline(AA>=KA,高,低,0,0),colorred;

stickline(AA>=KA,AA,KA,6,0),colorred;

stickline(庄筹线>散筹线,庄筹线,0,0),colorwhite; 

 

3用IF

主图公式1:

A1:=Ma(C,5);{5日移动平均线}

A2:=Ma(C,10);{10日移动平均线}

A3:=(A1+A2)/2;{5、10日移动平均线之和除2的平均线,也就是中心线}

IF (A1>A2,A1,A3),Colorred,linethick2;{5日线大于10日且5日线交叉A3线显示粗红线}

IF (A1>A2,A2,A3),Colorred,linethick2;{5日线大于10日且10日线交叉A3线显示粗红线}

IF (A1<=A2,A1,A3),Color00ff00,linethick2;{5日线小于等于10日且5日线交叉A3线显示粗绿线}

IF (A1<=A2,A2,A3),Color00ff00,linethick2;{5日线小于等于10日且10日线交叉A3线显示粗绿线}

A3,colorwhite,linethick2;{中心线显示粗白线}

这是以中心线为轴通过A1、A2这两条线与中心线的交叉来变换颜色的。

主图公式2:

MA1:=MA(CLOSE,5);{5日移动平均线}

MA2:=MA(CLOSE,10);{10日移动平均线}

MA3:=MA(CLOSE,20);{20日移动平均线}

MA4:=MA(CLOSE,30);{30日移动平均线}

MAA:=MA(CLOSE,60);{60日移动平均线}

MA5:IF(MA1<MA4,MA1,MA4),COLOR00ff00;{MA1线小于MA4且MA1线交叉MA4线显示绿色线}

IF(MA1<MA4,MA4,MA1),coloryellow;{MA1线小于MA4且MA4线交叉MA1线显示黄色线}

MA10:if(ma2<ma4,ma2,ma4),colorffcc66;{MA2线小于MA4且MA2线交叉MA4线显示青色线}

if(ma2<ma4,ma4,ma2),color0099ff;{MA2线小于MA4且MA4线交叉MA2线显示橘黄色线}

MA20:if(ma3<ma4,ma3,ma4),colorwhite;{MA3线小于MA4且MA3线交叉MA4线显示白色线}

if(ma3<ma4,ma4,ma3),colorblue;{MA3线小于MA4且MA4线交叉MA3线显示青色线}

MA30:if(ma4<maa,ma4,maa),colorff00ff,linethick2;{MA4线小于MAA且MA4线交叉MAA线显示粉色粗线}

if(ma4<maa,maa,ma4),colorred,linethick2;{MA4线小于MAA且MAA线交叉MA4线显示红色粗线}

MA60:if(ma4>maa,maa,maa),linethick2,colorblue;{MA4线大于MAA且MAA线交叉MAA线显示兰色粗线}

这是分别以MA4、MAA线为轴通过向上交叉和向下交叉来变换颜色的。

单条变色线

ma10:ma(c,10);

if(ma10>ref(ma10,1),ma10,0),Circledot,COLORRED,LINETHICK2;

if(ma10<ref(ma10,1),ma10,0),Circledot,COLOR00FF00,LINETHICK2;

 

一、线形函数

线形函数要和其它指标函数一起用才能发挥效力,因为它们都是描述其它指标函数的。正确用好线形函数可以使主副图指标显示丰富多彩,色彩缤纷。

1、函数:STICK 说明:画棒状线,STICK的英文是棍、棒的意思。

如副图公式:C>REF(C,1) AND C>REF(C,2),STICK;

2、函数:COLORSTICK 说明:以零轴为中心画彩色棒状线,零轴下为阴线颜色,零轴上为阳线颜色,这样零轴就如楚汉交界,泾渭分明了。

如副图公式:C-REF(C,1),COLORSTICK;

3、函数:LINESTICK 说明:同时画棒状线与指标线。LINE是线,STICK是棒,LINESTICK自然是线棒一起显示了。如副图公式:

A:=C-REF(C,1);

A,LINESTICK;

即想显示指标线和棒状线,又想以零轴为中心上下显示两种彩色棒状线,可以用分开的两句语句来达到目的,如副图公式:

A:=C-REF(C,1);

A,LINESTICK;

A,COLORSTICK;

4、函数:VOLSTICK 说明:画成交量柱状线。这是专门为显示成交量设计的。如副图公式:

VOL,VOLSTICK;

5、函数:CROSSDOT 说明:画叉状线或x状线。CROSS是交叉,DOT是点。如副图公式:

ma1:ma(c,30),CROSSDOT;

6、函数:CIRCLEDOT 说明:画小圆圈线,如副图公式:

ma1:ma(c,30),CIRCLEDOT;

7、函数:LINETHICK 说明:改变指标线粗细。取1、2、3、4、5、6、7放在LINETHICK后面如:LINETHICK2,数字越大,线越粗,最大可取7。如副图公式:

例1:ma1:ma(close,30),COLORFF00FF,linethick2;

例2:A:=C-REF(C,1);

    A,COLORSTICK,LINETHICK4;

8、函数:POINTDOT 说明:画点状线,POINT是点、加点的意思。这个点状线看起来有点太小了,可以用加粗线函数。如副图公式:

ma1:ma(c,30),COLOR00FF00,POINTDOT,LINETHICK2;

我们编个指标,看看都用了哪些线形函数。

{顶底指标}

股价趋势:3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;

底部警戒:10,COLORFFCCCC,POINTDOT;

买入警戒:IF(股价趋势<=10,40,0),stick,linethick3,coloryellow;

买入信号:IF(CROSS(股价趋势,底部警戒),80,0),stick,linethick3,colorblue;

强弱分界:50,COLORWHITE,POINTDOT,LINETHICK2;

顶部警戒:90,COLORFFCC66,POINTDOT;

卖出警戒:IF(股价趋势>=85,40,0),stick,linethick3,colorred;

卖出信号:IF(CROSS(股价趋势,顶部警戒),80,0),stick,linethick3,color00ff00;

指标解析:

{顶底指标}

股价趋势:3*移动平均((收盘价-最低值(最低价,27))/(最高值(最高价,27)-最低值(最低价,27))*100,5,1)-2*移动平均(移动平均((收盘价-最低值(最低价,27))/(最高值(最高价,27)-最低值(最低价,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;

底部警戒:10,COLORFFCCCC,点状线;

买入警戒:条件函数(股价趋势<=10,40,0),棒状线,linethick3,coloryellow;{黄粗棒状}

买入信号:条件函数(交叉函数(股价趋势,底部警戒),80,0),棒状线,linethick3,colorblue;{蓝粗棒状}

强弱分界:50,COLORWHITE,点状线,LINETHICK2;{粗点状线}

顶部警戒:90,COLORFFCC66,点状线;

卖出警戒:条件函数(股价趋势>=85,40,0),棒状线,linethick3,colorred;{红粗棒状}

卖出信号:条件函数(交叉函数(股价趋势,顶部警戒),80,0),棒状线,linethick3,color00ff00;{绿粗棒状}

二绘图函数

绘图函数的功能是在主图或副图上设定条件输出图标、直线、文字、数字、指标线、指标柱等。运用恰当使编制出的主副图指标给以视觉上的美感。

1、函数RAWICON

用法RAWICON(COND,PRICE,TYPE),当COND条件满足时,在PRICE位置画TYPE号图标。

说明:在图形上绘制小图标,其中TYPE可选3种图标,编码为1-3(1为红脸、2为绿脸、3为平脸)。

示例:DRAWICON(CLOSE>OPEN,LOW,1);表示当收阳时在最低价位置画1号图标,也就是红脸。

      DRAWICON(CLOSE<OPEN,high,2);表示当收阴时在最高价位置画2号图标,也就是绿脸。

指标示例:

{月均线主图}

ma1:ma(close,5),colorwhite,linethick2;{画一条5日收盘价的均线,设置该线为粗白色}

ma2:ma(close,10),colorff00ff,linethick2;{画一条10日收盘价的均线,设置该线为粗粉色}

ma3:ma(close,20),color00ff00,linethick2;{画一条20日收盘价的均线,设置该线为粗绿色}

a1:=cross(ma1,ma2);{5日均线上穿10日均线,金叉}

a2:=cross(ma2,ma1);{10日均线下穿5日均线,死叉}

DRAWICON(a1,low,1);{当a1条件满足时,在最低价位置上显示红脸,表示此处可作为买入点}

DRAWICON(a2,high,2);{当a2条件满足时,在最高价位置上显示绿脸,表示此处可作为卖出点}

2、函数:DRAWLINE

用法RAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND),当COND1条件满足时,在PRICE1位置画直线起点,当COND2条件满足时,在PRICE2位置画直线终点,EXPAND为延长类型。 

说明:在图形上绘制直线段。

示例: DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1);表示在创20天新高与创20天新低之间画直线并且向右延长。

DRAWLINE是唯一一个一句里面用到两个COND的绘图函数。因为它需要两个点来决定一直线。

COND1相当于指定K线位置(横坐标),PRICE1相当于是指定价位(纵坐标),这样一个点在平面上的位置就决定了。

DRAWLINE是从第一点画到第二点的,即有起点与终点的顺序关系:第一点出现的时间,要在第二点之前。否则线是画不出来的。

EXPAND,扩张、发展,这里是延伸的意思吧。取0,不延长;取1,延长。实际上是取大于等于1的数就延长,小于1就不延长。

指标示例:

{季均线主图}

ema1:ema(close,20),colorff00ff;{画一条20日收盘价的均线,设置该线为粉色}

ema2:ema(close,40),color00ff00;{画一条40日收盘价的均线,设置该线为绿色}

ema3:ema(close,60),colorwhite,CIRCLEDOT;{画一条60日收盘价的均线,设置该线为白色o线}

DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,HIGH>=HHV(HIGH,20),HIGH,1),colorwhite;{表示在创20天新高与创20天新低之间画直线并且向右延长。}

DRAWLINE(HIGH>=HHV(HIGH,20),HIGH,LOW<=LLV(LOW,20),LOW,1),coloryellow;{表示在创20天新高与创20天新低之间画直线并且向右延长。}

3、函数RAWTEXT 说明:在图形上显示文字。

用法RAWTEXT(COND,PRICE,TEXT),当COND条件满足时,在PRICE位置书写文字TEXT,可显示多行文本。

示例RAWTEXT(CLOSE/OPEN>1.08,LOW,''大涨啦'');表示当日涨幅大于8%时在最低价位置显示''大涨啦''字样。在某些满足条件的地方直接显示文字或字符,比显示图标要更直观一些。注意,显示的文字要用英语状态下的单引号括起。

指标示例:

{长短结合主图}

sma1:sma(close,5,1),color00ff00;{画一条5日收盘价的均线,设置该线为绿色}

sma2:sma(close,10,1),coloryellow;{画一条10日收盘价的均线,设置该线为黄色}

sma3:sma(close,60,1),colorblue,linethick2;{画一条60日收盘价的均线,设置该线为蓝色粗线}

DRAWTEXT(CLOSE/OPEN>1.08,LOW,''大涨啦''),colorwhite;{表示当日涨幅大于8%时在最低价位置显示''大涨啦''字样。}

4、函数:POLYLINE 说明:在图形上绘制折线段。

用法:POLYLINE(COND,PRICE),当COND条件满足时,以PRICE位置为顶点画折线连接。

示例:POLYLINE(HIGH>=HHV(HIGH,20),HIGH);表示在创20天新高点之间画折线。

指标示例:

{长短结合主图}

sma1:sma(close,5,1),color00ff00;{画一条5日收盘价的均线,设置该线为绿色}

sma2:sma(close,10,1),coloryellow;{画一条10日收盘价的均线,设置该线为黄色}

sma3:sma(close,60,1),colorblue,linethick2;{画一条60日收盘价的均线,设置该线为蓝色粗线}

POLYLINE(HIGH>=HHV(HIGH,20),HIGH),COLORWHITE;{表示在创20天新高点之间画折线(白色)。}

5、函数:STICKLINE 说明:在图形上绘制柱线。

用法: STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),当COND条件满足时,在PRICE1和PRICE2位置之间画柱状线,宽度为WIDTH可为0---100(10为标准间距),EMPTH不为0则画空心柱。

示例:STICKLINE(CLOSE>OPEN,CLOSE,OPEN,4,1);表示画K线中阳线的空心柱体部分。

运用要点:

⑴PRICE1和PRICE2没有顺序关系,即何者在前何者在后都不影响语句的执行。

⑵WIDTH宽度,支持小数。用1和用0.1,会有很大的差别。取4时和主图的K线宽度差不多。

以下的副图公式,画出的K线,与主图中显示的K线差不多。

指标示例:

{副图K线}

STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,4,1),colorred;{画出红K实体}

STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{画出红K上影线}

STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{画出红K下影线}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,4,0),colorffcc66;{画出青K实体}

STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorffcc66;{画出青K影线。因为青K是实心的,所以影线从中穿过}

ma5:MA(C,5),colorwhite;

ma10:ma(c,10),colorff00ff;

绘图函数结合示例介绍完了,相信你一定有所收获吧,举一反三自己动手编个指标。不要怕失败,失败是成功之母。

三背景装饰

飞狐、分析家股软能将背景颜色通过渐变颜色函数装扮的很漂亮,那么大智慧股软能做到吗?能,但做出的背景色虽不如飞狐、分析家平滑漂亮,也能起到装扮的作用,效果也可以。

在大智慧设计背景色的原理主要是通过主、副图的坐标用画柱线函数STICKLINE或者设定坐标用颜色代码就可以完成。下面用实例来说明背景色的设计过程。

一、单色背景色,这是最简单实用的一种装饰方法。我们先来设计一个主图指标:

要领:1、设定坐标:STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;意思是CLOSE>0条件满足时,在坐标h*9.0至坐标l*0.01处画宽度为8的实体柱线(也就是在整个主图上添色)。

也可以这样设定STICKLINE(110,0,110,8,0),color7d7f0f;显示的是同样效果。

2、添色的源码必须在指标的头条位置上,否则会覆盖均线、K线、文字等图形。

3、必须另外编制K线,因为背景色会覆盖系统中的K线图。

4、可以把背景色分为五档、十挡或更多,同时注意与你的指标的最大值、最小值(也就是坐标)相匹配,否则会在指标中出现背景色残缺不全的情况。

5、用你喜欢的颜色需要结合调色器可随意自定义自己喜欢的颜色。不过可得有耐心啊!

指标示例一:

{多空密码主图}

STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;{设置背景,可以将这句源码复制粘贴到任意主图指标的头条位置上}

Var1:=(3*CLOSE+LOW+OPEN+HIGH)/6;

Var3:=(20*Var1+19*REF(Var1,1)+18*REF(Var1,2)+17*REF(Var1,3)+16*REF(Var1,4)+15*REF

(Var1,5)+14*REF(Var1,6)+13*REF(Var1,7)+12*REF(Var1,8)+11*REF(Var1,9)+10*REF

(Var1,10)+9*REF(Var1,11)+8*REF(Var1,12)+7*REF(Var1,13)+6*REF(Var1,14)+5*REF

(Var1,15)+4*REF(Var1,16)+3*REF(Var1,17)+2*REF(Var1,18)+REF(Var1,20))/221;

Var4:=MA(Var3,78),LINETHICK2;

Var5:=EMA(MA(CLOSE,3),34);

Var6:=MA(Var3,5);

Var7:=MA(Var3,9);

M60:MA(C,60),COLOREEFFFF,CIRCLEDOT;

STICKLINE(Var3>1.005*Var4,Var3,Var4,4,1),COLORYELLOW;

STICKLINE(IF(Var3<Var5,Var3<=1.015*Var4,Var3<=1.005*Var4),Var7,Var4,2,1),COLORffff88;

STICKLINE(Var3>Var6,Var3,Var7,4,1),COLORff88ff;

STICKLINE(IF(Var3<Var6,Var3<=1.015*Var6,Var3<=1.005*Var6),Var3,Var7,3,1),COLORFF6633;

STICKLINE(Var3>Var6,Var3,Var7,4,1),COLOR0000ff;

{下面是柱形K线,如果喜欢这样的K线,你可以复制粘贴到任意主图指标里面}

STICKLINE(C>=O,C,O,7,0),COLORRED;

STICKLINE(C>=O,C,O,4,0),COLOR7070ff;

STICKLINE(C>=O,C,O,2,0),COLORYELLOW;

STICKLINE(C>=O,H,L,0,0),COLORYELLOW;

STICKLINE(C<=O,C,O,7,0),COLORFF2020;

STICKLINE(C<=O,C,O,4,0),COLORFF6600;

STICKLINE(C<=O,C,O,2,0),colorffcc66;

STICKLINE(C<=O,H,L,0,0),colorffcc66;

M9:MA(C,9),COLORYELLOW;

生命线: MA(CLOSE,13),COLORYELLOW,LINETHICK2;

牛熊线: (EMA(CLOSE,5)*7+EMA(CLOSE,5)*3)/10,COLORFF00CC,LINETHICK2;

箱顶:MA(REF(HHV(CLOSE,30),1),2);

箱底:MA(REF(LLV(CLOSE,30),1),2);

AA:(MA(C,13)+MA(C,21)+MA(C,34)+MA(C,55))/4,COLORFF00FF;

半年线:ma(close,125),colorffcc66;

指标示例二:

{财出水面副图}

VAR2:=(CLOSE-LLV(LOW,20))/(HHV(HIGH,20)-LLV(LOW,20))*100;

VAR3:=SMA(SMA(VAR2,3,1),3,1)/28.57;

VAR4:=EMA(VAR3,5);

操盘:=3*VAR3-2*VAR4;

A1:=CROSS(操盘,VAR3) AND VAR3<2.1 and c>o;

40,colorred,pointdot;

STICKLINE(c>0,40,22,8,0),colorff8080;{设置背景,CLOSE>0条件满足时,在坐标40至坐标22处设置宽度为8的兰色背景}

STICKLINE(c>0,22,4,8,0),color916f87;{设置背景,CLOSE>0条件满足时,在坐标22至坐标4处设置宽度为8的深紫色背景}

stickline(a1,18,15,28,0),colorred;

stickline(a1,18,18,18,0),colorblue;

stickline(a1,8,8,9,0),colorffff00;

stickline(a1,6,6,4,0),colorffff00;

stickline(a1,10,10,12,0),colorffff00;

stickline(a1,12,12,20,0),colorffff00;

stickline(a1,14,14,24,0),colorffff00;

stickline(a1,16,34,0.1,0),colorc0c0c0;

stickline(a1,33,18,9,0),colorwhite;

drawtext(a1,36,''财出水面''),COLORWHITE;

VarE:=30+(REF(CLOSE,1)-REF(OPEN,1))/REF(OPEN,1)*100/1.5;

VarF:=30+(REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)*100/1.5;

Var10:=CROSS("KDJ.K"(9,3,3),"KDJ.J"(9,3,3)) AND "KDJ.D"(9,3,3)>13;

Var11:=CROSS(REF("KDJ.K"(9,3,3),1),REF("KDJ.J"(9,3,3),1)) AND REF("KDJ.D"(9,3,3),1)>13;

Var12:=CROSS(REF("KDJ.K"(9,3,3),2),REF("KDJ.J"(9,3,3),2)) AND REF("KDJ.D"(9,3,3),2)>12;

Var13:=Var10 OR Var11 OR Var12;

Var14:=REF("BIAS.BIAS2"(6,12,24),1)>2;

Var15:=REF("RSI.RSI1"(6,12,24),1)>(VarE+VarF)/1.8 AND REF("ROC.ROC"(12,6),1)-"ROC.ROC"(12,6)>0 AND Var13 AND Var14;

卖出:=Var15*100/15,color00ff00;

stickline(卖出,18,15,28,0),coloryellow;

stickline(卖出,18,18,18,0),colorblue;

stickline(卖出,8,8,9,0),colorffff00;

stickline(卖出,6,6,4,0),colorffff00;

stickline(卖出,10,10,12,0),colorffff00;

stickline(卖出,12,12,20,0),colorffff00;

stickline(卖出,14,14,24,0),colorffff00;

stickline(卖出,16,28,0.1,0),colorc0c0c0;

stickline(卖出,28,18,9,0),color00ff00;

drawtext(卖出,31,''落袋为安''),COLOR00FF00;

指标示例三:

{金叉死叉}

STICKLINE(100,0,100,8,0),colorff0098;{设置背景,100条件满足时,在坐标100至坐标0处设置宽度为8的紫兰色背景}

Var1:=EMA(HHV(HIGH,500),21);

Var2:=EMA(HHV(HIGH,250),21);

Var3:=EMA(HHV(HIGH,90),21);

Var4:=EMA(LLV(LOW,500),21);

Var5:=EMA(LLV(LOW,250),21);

Var6:=EMA(LLV(LOW,90),21);

Var7:=EMA((Var4*0.96+Var5*0.96+Var6*0.96+Var1*0.558+Var2*0.558+Var3*0.558)/6,21); Var8:=EMA((Var4*1.25+Var5*1.23+Var6*1.2+Var1*0.55+Var2*0.55+Var3*0.65)/6,21);

Var9:=EMA((Var4*1.3+Var5*1.3+Var6*1.3+Var1*0.68+Var2*0.68+Var3*0.68)/6,21);

VarA:=EMA((Var7*3+Var8*2+Var9)/6*1.738,21);

VarB:=REF(LOW,1);

VarC:=SMA(ABS(LOW-VarB),3,1)/SMA(MAX(LOW-VarB,0),3,1)*100;

VarD:=EMA(IF(CLOSE*1.35<=VarA,VarC*10,VarC/10),3);

VarE:=LLV(LOW,30);

VarF:=HHV(VarD,30);

Var10:=IF(MA(CLOSE,58),1,0);

Var11:=EMA(IF(LOW<=VarE,(VarD+VarF*2)/2,0),3)/618*Var10;

Var12:=IF(Var11>40,10,Var11);

STICKLINE(Var12>8,0,Var12,4,1), COLORFF00FF;

Var13:=HHV(HIGH,30);

Var14:=LLV(LOW,30);

能量K:EMA((CLOSE-Var14)/(Var13-Var14)*97,5),COLORRED,linethick2;

能量D:EMA((CLOSE-Var14)/(Var13-Var14)*100,15),linethick2,colorff9933;

底部峰:5,pointdot,linethick2,COLORFF00FF;

DRAWTEXT(CROSS(底部峰,能量K),能量d,''●''),COLORWHITE;

DRAWTEXT(CROSS(底部峰,能量K),能量K+15,''底部形成''),COLORWHITE;

大智慧:100,,pointdot,linethick2,color00ccff;

强弱分界:50,pointdot,COLORWHITE;

DRAWTEXT(CROSS(90,能量K),80,''●''),COLOR00FF00;

DRAWTEXT(CROSS(90,能量K),90,''有风险''),COLOR00FF00;

DRAWTEXT(CROSS(90,能量K),能量K+13,''●''),COLOR00FF00;

DRAWTEXT(CROSS(能量D,能量K),98,''死叉''),COLORFFCC66;

DRAWTEXT(CROSS(能量D,能量K),90,''●''),COLORFFCC66;

DRAWTEXT(CROSS(能量K,能量D),8,''金叉''),COLORYELLOW;

DRAWTEXT(CROSS(能量K,能量D),15,''●''),COLORYELLOW;

0,pointdot,linethick2,COLORFF00FF;

渐变色源码供参考:

STICKLINE(0 ,0,-1,15,0) ,COLORFF0098;

STICKLINE(10 ,10,0,15,0) ,COLORFF009A;

STICKLINE(20 ,20,10,15,0),COLORFF009C;

STICKLINE(30 ,30,20,15,0),COLORFF009E;

STICKLINE(40 ,40,30,15,0),COLORFF00A0;

STICKLINE(50 ,50,40,15,0),COLORFF00A2;

STICKLINE(60 ,60,50,15,0),COLORFF00A4;

STICKLINE(70 ,70,60,15,0),COLORFF00A6;

STICKLINE(80 ,80,70,15,0),COLORFF00A8;

STICKLINE(90 ,90,80,15,0),COLORFF00AA;

STICKLINE(100 ,100,90,15,0),COLORFF00AC;

STICKLINE(110 ,110,100,15,0),COLORFF00AF;

单色源码供参考:

STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;

K线

STICKLINE(C>=O,C,O,7,0),COLORRED;

STICKLINE(C>=O,C,O,4,0),COLOR7070ff;

STICKLINE(C>=O,C,O,2,0),COLORYELLOW;

STICKLINE(C>=O,H,L,0,0),COLORYELLOW;

STICKLINE(C<=O,C,O,7,0),COLORFF2020;

STICKLINE(C<=O,C,O,4,0),COLORFF6600;

STICKLINE(C<=O,C,O,2,0),colorffcc66;

STICKLINE(C<=O,H,L,0,0),colorffcc66;

副图背景色源码供参考:

STICKLINE(100,0,100,8,0),color7d7f0f;{注意指标的坐标,按不同的坐标做相应的调整,本例是100的坐标。

这些公式只为学习函数用,不做买卖参考。公式中是以分析家为主要对象表述的,时间久远了,假如不能和现在的软件配套了,不必强求。

0

阅读 评论 收藏 禁止转载 喜欢 打印举报/Report
  • 评论加载中,请稍候...
发评论

    发评论

    以上网友发言只代表其个人观点,不代表新浪网的观点或立场。

      

    新浪BLOG意见反馈留言板 电话:4000520066 提示音后按1键(按当地市话标准计费) 欢迎批评指正

    新浪简介 | About Sina | 广告服务 | 联系我们 | 招聘信息 | 网站律师 | SINA English | 会员注册 | 产品答疑

    新浪公司 版权所有